VLPOD交货单客户签收POD确认

FUNCTION zsdfm056.
*"----------------------------------------------------------------------
*"*"本地接口：
*" IMPORTING
*" VALUE(I_VBELN) TYPE VBELN_VL
*" VALUE(I_PODAT) TYPE PODAT OPTIONAL
*" VALUE(I_POTIM) TYPE POTIM OPTIONAL
*" VALUE(I_STYPE) TYPE ZDESTYPE OPTIONAL
*" EXPORTING
*" VALUE(E_MESSAGE) TYPE ZOTS001
*"----------------------------------------------------------------------
DATA:ls_vbkok_wa TYPE vbkok.
DATA:ls_vbpok_tab TYPE vbpok.
DATA:lt_vbpok_tab TYPE TABLE OF vbpok.
DATA:lt_prot TYPE TABLE OF prott WITH HEADER LINE.
DATA:lv_pdstk TYPE likp-pdstk.
DATA:lv_message TYPE bapiret2-message.
*-->初始化
i_vbeln = |{ i_vbeln ALPHA = IN }|.
*-->检查
IF i_vbeln IS INITIAL.
e_message-type = 'E'.
e_message-message = '交货单号必填'.
EXIT.
ENDIF.
SELECT SINGLE pdstk INTO lv_pdstk FROM likp WHERE vbeln = i_vbeln.
IF lv_pdstk = 'C'.
e_message-type = 'S'.
e_message-message = 'POD已经确认，无需再次确认'.
EXIT.
ELSEIF lv_pdstk = ''.
e_message-type = 'S'.
e_message-message = '交货单' && i_vbeln && '未启用POD，无需POD确认'.
EXIT.
ENDIF.
*-->BAPI赋值
"抬头
ls_vbkok_wa-vbeln_vl = i_vbeln.
ls_vbkok_wa-vbtyp_vl = 'J'.
IF i_podat IS NOT INITIAL.
ls_vbkok_wa-podat = i_podat.
ELSE.
ls_vbkok_wa-podat = sy-datum.
ENDIF.
IF i_potim IS NOT INITIAL.
ls_vbkok_wa-potim = i_potim.
ELSE.
ls_vbkok_wa-potim = sy-uzeit.
ENDIF.
ls_vbkok_wa-kzpod = 'B'."D/B
ls_vbkok_wa-wabuc = 'X'.
"行项目
SELECT vbeln,
posnr,
matnr,
charg,
lfimg,
vrkme,
lgmng,
meins
FROM lips
WHERE vbeln = @i_vbeln
INTO TABLE @DATA(lt_lips).
LOOP AT lt_lips INTO DATA(ls_lips).
CLEAR:ls_vbpok_tab.
ls_vbpok_tab-vbeln_vl = ls_lips-vbeln.
ls_vbpok_tab-posnr_vl = ls_lips-posnr.
ls_vbpok_tab-matnr = ls_lips-matnr.
ls_vbpok_tab-charg = ls_lips-charg.
ls_vbpok_tab-lfimg = ls_lips-lfimg.
ls_vbpok_tab-vrkme = ls_lips-vrkme.
ls_vbpok_tab-lgmng = ls_lips-lgmng.
ls_vbpok_tab-meins = ls_lips-meins.
APPEND ls_vbpok_tab TO lt_vbpok_tab.
ENDLOOP.
*-->BAPI调用
CALL FUNCTION 'WS_DELIVERY_UPDATE_2'
EXPORTING
vbkok_wa = ls_vbkok_wa
delivery = i_vbeln
TABLES
vbpok_tab = lt_vbpok_tab
prot = lt_prot.
LOOP AT lt_prot WHERE msgty CA 'AEX'.
CLEAR:lv_message.
CALL FUNCTION 'MESSAGE_TEXT_BUILD'
EXPORTING
msgid = lt_prot-msgid
msgnr = lt_prot-msgno
msgv1 = lt_prot-msgv1
msgv2 = lt_prot-msgv2
msgv3 = lt_prot-msgv3
msgv4 = lt_prot-msgv4
IMPORTING
message_text_output = lv_message.
IF e_message-message IS INITIAL.
e_message-message = lv_message.
ELSE.
e_message-message = e_message-message && '/' && lv_message.
ENDIF.
ENDLOOP.
IF sy-subrc = 0.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
e_message-type = 'E'.
ELSE.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
wait = 'X'.
*记录签收日期
SELECT SINGLE vbrp~vbeln INTO @DATA(lv_vbeln_vf) FROM vbrp WHERE vbrp~vgbel = @i_vbeln.
IF sy-subrc = 0.
SELECT SINGLE * INTO @DATA(ls_zsdt023) FROM zsdt023 WHERE vbeln_vf = @lv_vbeln_vf.
IF sy-subrc = 0.
IF ls_vbkok_wa-podat IS NOT INITIAL.
ls_zsdt023-sdate = ls_vbkok_wa-podat.
ENDIF.
IF i_stype IS NOT INITIAL.
ls_zsdt023-stype = i_stype.
ENDIF.
ls_zsdt023-erdat = sy-datum.
ls_zsdt023-erzet = sy-uzeit.
ls_zsdt023-ernam = sy-uname.
ELSE.
ls_zsdt023-vbeln_vf = lv_vbeln_vf.
ls_zsdt023-vbeln_vl = i_vbeln.
ls_zsdt023-sdate = ls_vbkok_wa-podat.
ls_zsdt023-stype = i_stype.
ls_zsdt023-erdat = sy-datum.
ls_zsdt023-erzet = sy-uzeit.
ls_zsdt023-ernam = sy-uname.
ENDIF.
MODIFY zsdt023 FROM ls_zsdt023.
COMMIT WORK AND WAIT.
ENDIF.
e_message-type = 'S'.
e_message-message = 'POD确认成功！'.
ENDIF.
ENDFUNCTION.

复制代码

[BAPI] VLPOD交货单客户签收POD确认

Ta最近发表

快速回帖