创建和修改物料主数据，自动识别有变动的字段

FUNCTION zmmfm014.
*"----------------------------------------------------------------------
*"*"本地接口：
*" EXPORTING
*" VALUE(E_MESSAGE) TYPE ZOTS001
*" TABLES
*" IT_MARA STRUCTURE ZMMS028
*" IT_MARC STRUCTURE ZMMS031 OPTIONAL
*" IT_MARD STRUCTURE ZMMS030 OPTIONAL
*" IT_MBEW STRUCTURE ZMMS033 OPTIONAL
*" IT_MVKE STRUCTURE ZMMS035 OPTIONAL
*" IT_MARM STRUCTURE ZMMS032 OPTIONAL
*" IT_MLAN STRUCTURE ZMMS034 OPTIONAL
*" IT_MAKT STRUCTURE ZMMS029 OPTIONAL
*" IT_MLTX STRUCTURE ZMMS036 OPTIONAL
*"----------------------------------------------------------------------
DATA:lv_value TYPE trdir-name.
READ TABLE it_mara ASSIGNING FIELD-SYMBOL(<fs_mara>) INDEX 1.
IF sy-subrc = 0.
lv_value = <fs_mara>-material.
ELSE.
EXIT.
ENDIF.
*加锁
IF lv_value IS NOT INITIAL.
CALL METHOD zcl_lock=>enqueue
EXPORTING
i_name = 'ZMMFM014'
i_value = lv_value
i_timeout = '3000' "3000ms = 3s
i_interval = '1000' "1000ms = 1s
IMPORTING
e_message = e_message.
IF e_message-type = 'E'.
EXIT.
ENDIF.
ENDIF.
PERFORM frm_call_bapi_data TABLES it_mara it_marc it_mard it_mbew it_mvke it_makt it_marm it_mltx it_mlan
CHANGING e_message.
*解锁
IF lv_value IS NOT INITIAL.
CALL METHOD zcl_lock=>dequeue
EXPORTING
i_name = 'ZMMFM014'
i_value = lv_value.
ENDIF.
ENDFUNCTION.

复制代码

*----------------------------------------------------------------------*
***INCLUDE LZMMFG014F01.
*----------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*& Form FRM_CALL_BAPI_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> IT_MARC
*& --> IT_MARCX
*& --> IT_MARD
*& --> IT_MARDX
*& --> IT_MBEW
*& --> IT_MBEWX
*& --> IT_MVKE
*& --> IT_MVKEX
*& --> IT_MAKT
*& --> IT_MARM
*& --> IT_MARMX
*& --> IT_MLTX
*& --> IT_MLAN
*& --> I_HEADDATA
*& --> I_MARA
*& --> I_MARAX
*& <-- E_MESSAGE
*&---------------------------------------------------------------------*
FORM frm_call_bapi_data TABLES pt_mara STRUCTURE zmms028
pt_marc STRUCTURE zmms031
pt_mard STRUCTURE zmms030
pt_mbew STRUCTURE zmms033
pt_mvke STRUCTURE zmms035
pt_makt STRUCTURE zmms029
pt_marm STRUCTURE zmms032
pt_mltx STRUCTURE zmms036
pt_mlan STRUCTURE zmms034
CHANGING pc_message TYPE zots001.
DATA:ls_return TYPE bapiret2.
DATA:lt_returnmessages TYPE TABLE OF bapie1ret2 WITH HEADER LINE.
DATA:lt_head TYPE TABLE OF bapie1matheader.
DATA:lt_mara TYPE TABLE OF bapie1mara WITH HEADER LINE.
DATA:lt_marax TYPE TABLE OF bapie1marax WITH HEADER LINE.
DATA:lt_marc TYPE TABLE OF bapie1marc WITH HEADER LINE.
DATA:lt_marcx TYPE TABLE OF bapie1marcx WITH HEADER LINE.
DATA:lt_mard TYPE TABLE OF bapie1mard WITH HEADER LINE.
DATA:lt_mardx TYPE TABLE OF bapie1mardx WITH HEADER LINE.
DATA:lt_mbew TYPE TABLE OF bapie1mbew WITH HEADER LINE.
DATA:lt_mbewx TYPE TABLE OF bapie1mbewx WITH HEADER LINE.
DATA:lt_mvke TYPE TABLE OF bapie1mvke WITH HEADER LINE.
DATA:lt_mvkex TYPE TABLE OF bapie1mvkex WITH HEADER LINE.
DATA:lt_makt TYPE TABLE OF bapie1makt WITH HEADER LINE.
DATA:lt_marm TYPE TABLE OF bapie1marm WITH HEADER LINE.
DATA:lt_marmx TYPE TABLE OF bapie1marmx WITH HEADER LINE.
DATA:lt_mltx TYPE TABLE OF bapie1mltx WITH HEADER LINE.
DATA:lt_mlan TYPE TABLE OF bapie1mlan WITH HEADER LINE.
DATA:ls_head TYPE bapie1matheader.
DATA:lv_matnr TYPE mara-matnr.
READ TABLE pt_mara ASSIGNING FIELD-SYMBOL(<fs_mara>) INDEX 1.
IF sy-subrc = 0.
PERFORM frm_conversion_matnr_input CHANGING <fs_mara>-material.
lv_matnr = <fs_mara>-material.
ENDIF.
*-->默认数据
LOOP AT pt_mara ASSIGNING <fs_mara>.
<fs_mara>-trans_grp = '0001'.
ENDLOOP.
LOOP AT pt_marc ASSIGNING FIELD-SYMBOL(<fs_marc>).
<fs_marc>-sm_key = '001'.
<fs_marc>-availcheck = '02'.
<fs_marc>-loadinggrp = '0001'.
<fs_marc>-mrp_type = 'PD'.
<fs_marc>-dep_req_id = '2'.
<fs_marc>-production_scheduler = 'SG1'.
<fs_marc>-prodprof = '000001'.
<fs_marc>-lotsizekey = 'EX'.
ENDLOOP.
LOOP AT pt_mvke ASSIGNING FIELD-SYMBOL(<fs_mvke>).
<fs_mvke>-matl_stats = '1'. "纳入统计
ENDLOOP.
LOOP AT pt_mbew ASSIGNING FIELD-SYMBOL(<fs_mbew>).
<fs_mbew>-qty_struct = 'X'.
<fs_mbew>-orig_mat = 'X'.
ENDLOOP.
*-->填充数据
PERFORM frm_fill_mara_data TABLES pt_mara lt_mara lt_marax USING lv_matnr CHANGING ls_head.
PERFORM frm_fill_marc_data TABLES pt_marc lt_marc lt_marcx USING lv_matnr CHANGING ls_head.
PERFORM frm_fill_mard_data TABLES pt_mard lt_mard lt_mardx USING lv_matnr CHANGING ls_head.
PERFORM frm_fill_mbew_data TABLES pt_mbew lt_mbew lt_mbewx USING lv_matnr CHANGING ls_head.
PERFORM frm_fill_mvke_data TABLES pt_mvke lt_mvke lt_mvkex USING lv_matnr CHANGING ls_head.
PERFORM frm_fill_marm_data TABLES pt_marm lt_marm lt_marmx USING lv_matnr CHANGING ls_head.
PERFORM frm_fill_mlan_data TABLES pt_mlan lt_mlan USING lv_matnr.
PERFORM frm_fill_makt_data TABLES pt_makt lt_makt USING lv_matnr.
PERFORM frm_fill_mltx_data TABLES pt_mltx lt_mltx USING lv_matnr.
IF ls_head IS NOT INITIAL.
APPEND ls_head TO lt_head.
ENDIF.
*-->调用BAPI
CALL FUNCTION 'BAPI_MATERIAL_SAVEREPLICA'
EXPORTING
noappllog = ''
nochangedoc = ''
testrun = ''
inpfldcheck = ''
IMPORTING
return = ls_return
TABLES
headdata = lt_head[]
clientdata = lt_mara[]
clientdatax = lt_marax[]
plantdata = lt_marc[]
plantdatax = lt_marcx[]
storagelocationdata = lt_mard[]
storagelocationdatax = lt_mardx[]
valuationdata = lt_mbew[]
valuationdatax = lt_mbewx[]
salesdata = lt_mvke[]
salesdatax = lt_mvkex[]
materialdescription = lt_makt[]
unitsofmeasure = lt_marm[]
unitsofmeasurex = lt_marmx[]
materiallongtext = lt_mltx[]
taxclassifications = lt_mlan[]
returnmessages = lt_returnmessages[].
IF ls_return-type CA 'AXE'.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
pc_message-type = 'E'.
LOOP AT lt_returnmessages WHERE type CA 'AXE'.
IF pc_message-message IS INITIAL.
pc_message-message = lt_returnmessages-message.
ELSE.
CONCATENATE pc_message-message lt_returnmessages-message INTO pc_message-message SEPARATED BY '/'.
ENDIF.
ENDLOOP.
ELSE.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
wait = 'X'.
pc_message-type = 'S'.
pc_message-message = '物料维护成功！'.
ENDIF.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_CONVERSION_MATNR_INPUT
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& <-- <FS_MLTX>_TEXT_NAME
*&---------------------------------------------------------------------*
FORM frm_conversion_matnr_input CHANGING pc_matnr.
CALL FUNCTION 'CONVERSION_EXIT_MATN1_INPUT'
EXPORTING
input = pc_matnr
IMPORTING
output = pc_matnr
EXCEPTIONS
length_error = 1
OTHERS = 2.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MARA_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MARA
*& --> LT_MARA
*& --> LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_mara_data TABLES pt_mara STRUCTURE zmms028
lt_mara STRUCTURE bapie1mara
lt_marax STRUCTURE bapie1marax
USING pi_matnr TYPE mara-matnr
CHANGING pc_head TYPE bapie1matheader.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_mara TYPE bapie1mara.
DATA:ls_marax TYPE bapie1marax.
CLEAR:lt_mara[],lt_marax[].
LOOP AT pt_mara ASSIGNING FIELD-SYMBOL(<fs_mara>).
PERFORM frm_conversion_matnr_input CHANGING <fs_mara>-material.
PERFORM frm_conversion_cunit_input CHANGING <fs_mara>-base_uom.
PERFORM frm_conversion_cunit_input CHANGING <fs_mara>-unit_of_wt.
CALL FUNCTION 'CONVERSION_EXIT_PERKZ_INPUT'
EXPORTING
input = <fs_mara>-period_ind_expiration_date
IMPORTING
output = <fs_mara>-period_ind_expiration_date.
ENDLOOP.
SELECT matnr AS material,
meins AS base_uom,
matkl AS matl_group,
spart AS division,
labor AS dsn_office,
prdha AS prod_hier,
mstae AS pur_status,
mstde AS pvalidfrom,
gewei AS unit_of_wt,
ntgew AS net_weight,
ferth AS prod_memo,
normt AS std_descr,
mstav AS sal_status,
mstdv AS svalidfrom,
xchpf AS batch_mgmt,
tragr AS trans_grp,
tempb AS temp_conds,
mhdrz AS minremlife,
mhdhb AS shelf_life,
iprkz AS period_ind_expiration_date
FROM mara
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_mara_db).
SORT lt_mara_db BY material.
LOOP AT pt_mara ASSIGNING FIELD-SYMBOL(<fs_mara_pi>).
CLEAR:ls_mara,ls_marax.
READ TABLE lt_mara_db ASSIGNING FIELD-SYMBOL(<fs_mara_db>) WITH KEY material = <fs_mara_pi>-material BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mara_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mara_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mara_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mara TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marax TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_marax IS NOT INITIAL.
ls_mara-function = 'UPD'.
ls_mara-material = <fs_mara_pi>-material.
APPEND ls_mara TO lt_mara.
pc_head-basic_view = 'X'.
ls_marax-function = 'UPD'.
ls_marax-material = <fs_mara_pi>-material.
APPEND ls_marax TO lt_marax.
ENDIF.
pc_head-function = 'UPD'.
pc_head-material = <fs_mara_pi>-material.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mara_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mara_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mara TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marax TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_marax IS NOT INITIAL.
ls_mara-function = 'INS'.
ls_mara-material = <fs_mara_pi>-material.
APPEND ls_mara TO lt_mara.
ls_marax-function = 'INS'.
ls_marax-material = <fs_mara_pi>-material.
APPEND ls_marax TO lt_marax.
ENDIF.
pc_head-function = 'INS'.
pc_head-material = <fs_mara_pi>-material.
pc_head-ind_sector = 'C'."化学
pc_head-matl_type = 'A001'."成品
pc_head-basic_view = 'X'.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MARC_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MARC
*& --> LT_MARC
*& --> LT_MARCX
*& --> LV_MATNR
*& <-- LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_marc_data TABLES pt_marc STRUCTURE zmms031
lt_marc STRUCTURE bapie1marc
lt_marcx STRUCTURE bapie1marcx
USING pi_matnr TYPE mara-matnr
CHANGING pc_head TYPE bapie1matheader.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_marc TYPE bapie1marc.
DATA:ls_marcx TYPE bapie1marcx.
CLEAR:lt_marc[],lt_marcx[].
LOOP AT pt_marc ASSIGNING FIELD-SYMBOL(<fs_marc>).
PERFORM frm_conversion_matnr_input CHANGING <fs_marc>-material.
<fs_marc>-profit_ctr = |{ <fs_marc>-profit_ctr ALPHA = IN }|.
PERFORM frm_conversion_cunit_input CHANGING <fs_marc>-prod_unit.
ENDLOOP.
SELECT matnr AS material,
werks AS plant,
mtvfp AS availcheck,
xchpf AS batch_mgmt,
ladgr AS loadinggrp,
prctr AS profit_ctr,
ekgrp AS pur_group,
disgr AS mrp_group,
mmsta AS pur_status,
mmstd AS pvalidfrom,
dismm AS mrp_type,
dispo AS mrp_ctrler,
disls AS lotsizekey,
beskz AS proc_type,
sobsl AS spproctype,
lgpro AS iss_st_loc,
dzeit AS inhseprodt,
webaz AS gr_pr_time,
plifz AS plnd_delry,
fhori AS sm_key,
strgr AS plan_strgp,
eisbe AS safety_stk,
eislo AS min_safety_stk,
sbdkz AS dep_req_id,
frtme AS prod_unit,
fevor AS production_scheduler,
sfcpf AS prodprof,
prfrq AS insp_int,
losgr AS lot_size
FROM marc
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_marc_db).
SORT lt_marc_db BY material plant.
LOOP AT pt_marc ASSIGNING FIELD-SYMBOL(<fs_marc_pi>).
CLEAR:ls_marc,ls_marcx.
READ TABLE lt_marc_db ASSIGNING FIELD-SYMBOL(<fs_marc_db>) WITH KEY material = <fs_marc_pi>-material plant = <fs_marc_pi>-plant BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_marc_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_marc_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_marc_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marc TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marcx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_marcx IS NOT INITIAL.
ls_marc-function = 'UPD'.
ls_marc-material = <fs_marc_pi>-material.
ls_marc-plant = <fs_marc_pi>-plant.
APPEND ls_marc TO lt_marc.
ls_marcx-function = 'UPD'.
ls_marcx-material = <fs_marc_pi>-material.
ls_marcx-plant = <fs_marc_pi>-plant.
APPEND ls_marcx TO lt_marcx.
pc_head-storage_view = 'X'.
IF ls_marc-proc_type = 'F' OR ls_marc-proc_type = 'X'."F 外部采购,X 两种采购类型
pc_head-purchase_view = 'X'.
ENDIF.
IF ls_marc-proc_type NE ''."采购和生产都要扩MRP视图
pc_head-mrp_view = 'X'.
ENDIF.
pc_head-work_sched_view = 'X'.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_marc_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_marc_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marc TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marcx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_marcx IS NOT INITIAL.
ls_marc-function = 'INS'.
ls_marc-material = <fs_marc_pi>-material.
ls_marc-plant = <fs_marc_pi>-plant.
APPEND ls_marc TO lt_marc.
ls_marcx-function = 'INS'.
ls_marcx-material = <fs_marc_pi>-material.
ls_marcx-plant = <fs_marc_pi>-plant.
APPEND ls_marcx TO lt_marcx.
pc_head-storage_view = 'X'.
IF ls_marc-proc_type = 'F' OR ls_marc-proc_type = 'X'."F 外部采购,X 两种采购类型
pc_head-purchase_view = 'X'.
ENDIF.
IF ls_marc-proc_type NE ''."采购和生产都要扩MRP视图
pc_head-mrp_view = 'X'.
ENDIF.
pc_head-work_sched_view = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MARD_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MARD
*& --> LT_MARD
*& --> LT_MARDX
*& --> LV_MATNR
*& <-- LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_mard_data TABLES pt_mard STRUCTURE zmms030
lt_mard STRUCTURE bapie1mard
lt_mardx STRUCTURE bapie1mardx
USING pi_matnr TYPE mara-matnr
CHANGING pc_head TYPE bapie1matheader.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_mard TYPE bapie1mard.
DATA:ls_mardx TYPE bapie1mardx.
CLEAR:lt_mard[],lt_mardx[].
LOOP AT pt_mard ASSIGNING FIELD-SYMBOL(<fs_mard>).
PERFORM frm_conversion_matnr_input CHANGING <fs_mard>-material.
ENDLOOP.
SELECT matnr AS material,
werks AS plant,
lgort AS stge_loc,
lgpbe AS stge_bin
FROM mard
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_mard_db).
SORT lt_mard_db BY material plant stge_loc.
LOOP AT pt_mard ASSIGNING FIELD-SYMBOL(<fs_mard_pi>).
CLEAR:ls_mard,ls_mardx.
READ TABLE lt_mard_db ASSIGNING FIELD-SYMBOL(<fs_mard_db>) WITH KEY material = <fs_mard_pi>-material plant = <fs_mard_pi>-plant stge_loc = <fs_mard_pi>-stge_loc BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mard_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mard_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mard_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mard TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mardx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mardx IS NOT INITIAL.
ls_mard-function = 'UPD'.
ls_mard-material = <fs_mard_pi>-material.
ls_mard-plant = <fs_mard_pi>-plant.
ls_mard-stge_loc = <fs_mard_pi>-stge_loc.
APPEND ls_mard TO lt_mard.
ls_mardx-function = 'UPD'.
ls_mardx-material = <fs_mard_pi>-material.
ls_mardx-plant = <fs_mard_pi>-plant.
ls_mardx-stge_loc = <fs_mard_pi>-stge_loc.
APPEND ls_mardx TO lt_mardx.
pc_head-storage_view = 'X'.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mard_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mard_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mard TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mardx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mardx IS NOT INITIAL.
ls_mard-function = 'INS'.
ls_mard-material = <fs_mard_pi>-material.
ls_mard-plant = <fs_mard_pi>-plant.
ls_mard-stge_loc = <fs_mard_pi>-stge_loc.
APPEND ls_mard TO lt_mard.
ls_mardx-function = 'INS'.
ls_mardx-material = <fs_mard_pi>-material.
ls_mardx-plant = <fs_mard_pi>-plant.
ls_mardx-stge_loc = <fs_mard_pi>-stge_loc.
APPEND ls_mardx TO lt_mardx.
pc_head-storage_view = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MBEW_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MBEW
*& --> LT_MBEW
*& --> LT_MBEWX
*& --> LV_MATNR
*& <-- LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_mbew_data TABLES pt_mbew STRUCTURE zmms033
lt_mbew STRUCTURE bapie1mbew
lt_mbewx STRUCTURE bapie1mbewx
USING pi_matnr TYPE mara-matnr
CHANGING pc_head TYPE bapie1matheader.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_mbew TYPE bapie1mbew.
DATA:ls_mbewx TYPE bapie1mbewx.
CLEAR:lt_mbew[],lt_mbewx[].
LOOP AT pt_mbew ASSIGNING FIELD-SYMBOL(<fs_mbew>).
PERFORM frm_conversion_matnr_input CHANGING <fs_mbew>-material.
ENDLOOP.
SELECT matnr AS material,
bwkey AS val_area,
bklas AS val_class,
vprsv AS price_ctrl,
mlast AS ml_settle,
ekalr AS qty_struct,
hkmat AS orig_mat
FROM mbew
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_mbew_db).
SORT lt_mbew_db BY material val_area.
LOOP AT pt_mbew ASSIGNING FIELD-SYMBOL(<fs_mbew_pi>).
CLEAR:ls_mbew,ls_mbewx.
READ TABLE lt_mbew_db ASSIGNING FIELD-SYMBOL(<fs_mbew_db>) WITH KEY material = <fs_mbew_pi>-material val_area = <fs_mbew_pi>-val_area BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mbew_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mbew_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mbew_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mbew TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mbewx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mbewx IS NOT INITIAL.
ls_mbew-function = 'UPD'.
ls_mbew-material = <fs_mbew_pi>-material.
ls_mbew-val_area = <fs_mbew_pi>-val_area.
APPEND ls_mbew TO lt_mbew.
ls_mbewx-function = 'UPD'.
ls_mbewx-material = <fs_mbew_pi>-material.
ls_mbewx-val_area = <fs_mbew_pi>-val_area.
APPEND ls_mbewx TO lt_mbewx.
pc_head-account_view = 'X'.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mbew_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mbew_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mbew TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mbewx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mbewx IS NOT INITIAL.
ls_mbew-function = 'INS'.
ls_mbew-material = <fs_mbew_pi>-material.
ls_mbew-val_area = <fs_mbew_pi>-val_area.
APPEND ls_mbew TO lt_mbew.
ls_mbewx-function = 'INS'.
ls_mbewx-material = <fs_mbew_pi>-material.
ls_mbewx-val_area = <fs_mbew_pi>-val_area.
APPEND ls_mbewx TO lt_mbewx.
pc_head-account_view = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MVKE_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MVKE
*& --> LT_MVKE
*& --> LT_MVKEX
*& --> LV_MATNR
*& <-- LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_mvke_data TABLES pt_mvke STRUCTURE zmms035
lt_mvke STRUCTURE bapie1mvke
lt_mvkex STRUCTURE bapie1mvkex
USING pi_matnr TYPE mara-matnr
CHANGING pc_head TYPE bapie1matheader.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_mvke TYPE bapie1mvke.
DATA:ls_mvkex TYPE bapie1mvkex.
CLEAR:lt_mvke[],lt_mvkex[].
LOOP AT pt_mvke ASSIGNING FIELD-SYMBOL(<fs_mvke>).
PERFORM frm_conversion_matnr_input CHANGING <fs_mvke>-material.
PERFORM frm_conversion_cunit_input CHANGING <fs_mvke>-sales_unit.
ENDLOOP.
SELECT matnr AS material,
vkorg AS sales_org,
vtweg AS distr_chan,
vrkme AS sales_unit,
vmsta AS sal_status,
vmstd AS valid_from,
dwerk AS delyg_plnt,
versg AS matl_stats,
ktgrm AS acct_assgt,
mtpos AS item_cat,
mvgr1 AS matl_grp_1,
mvgr2 AS matl_grp_2,
prodh AS prod_hier
FROM mvke
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_mvke_db).
SORT lt_mvke_db BY material sales_org distr_chan.
LOOP AT pt_mvke ASSIGNING FIELD-SYMBOL(<fs_mvke_pi>).
CLEAR:ls_mvke,ls_mvkex.
READ TABLE lt_mvke_db ASSIGNING FIELD-SYMBOL(<fs_mvke_db>) WITH KEY material = <fs_mvke_pi>-material sales_org = <fs_mvke_pi>-sales_org distr_chan = <fs_mvke_pi>-distr_chan BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mvke_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mvke_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mvke_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mvke TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mvkex TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mvkex IS NOT INITIAL.
ls_mvke-function = 'UPD'.
ls_mvke-material = <fs_mvke_pi>-material.
ls_mvke-sales_org = <fs_mvke_pi>-sales_org.
ls_mvke-distr_chan = <fs_mvke_pi>-distr_chan.
APPEND ls_mvke TO lt_mvke.
ls_mvkex-function = 'UPD'.
ls_mvkex-material = <fs_mvke_pi>-material.
ls_mvkex-sales_org = <fs_mvke_pi>-sales_org.
ls_mvkex-distr_chan = <fs_mvke_pi>-distr_chan.
APPEND ls_mvkex TO lt_mvkex.
pc_head-sales_view = 'X'.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mvke_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mvke_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mvke TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mvkex TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mvkex IS NOT INITIAL.
ls_mvke-function = 'INS'.
ls_mvke-material = <fs_mvke_pi>-material.
ls_mvke-sales_org = <fs_mvke_pi>-sales_org.
ls_mvke-distr_chan = <fs_mvke_pi>-distr_chan.
APPEND ls_mvke TO lt_mvke.
ls_mvkex-function = 'INS'.
ls_mvkex-material = <fs_mvke_pi>-material.
ls_mvkex-sales_org = <fs_mvke_pi>-sales_org.
ls_mvkex-distr_chan = <fs_mvke_pi>-distr_chan.
APPEND ls_mvkex TO lt_mvkex.
pc_head-sales_view = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MARM_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MARM
*& --> LT_MARM
*& --> LT_MARMX
*& --> LV_MATNR
*& <-- LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_marm_data TABLES pt_marm STRUCTURE zmms032
lt_marm STRUCTURE bapie1marm
lt_marmx STRUCTURE bapie1marmx
USING pi_matnr TYPE mara-matnr
CHANGING pc_head TYPE bapie1matheader.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_marm TYPE bapie1marm.
DATA:ls_marmx TYPE bapie1marmx.
CLEAR:lt_marm[],lt_marmx[].
LOOP AT pt_marm ASSIGNING FIELD-SYMBOL(<fs_marm>).
PERFORM frm_conversion_matnr_input CHANGING <fs_marm>-material.
PERFORM frm_conversion_cunit_input CHANGING <fs_marm>-alt_unit.
PERFORM frm_conversion_cunit_input CHANGING <fs_marm>-unit_of_wt.
PERFORM frm_conversion_cunit_input CHANGING <fs_marm>-volumeunit.
ENDLOOP.
SELECT matnr AS material,
meinh AS alt_unit,
umrez AS numerator,
umren AS denominatr,
brgew AS gross_wt,
gewei AS unit_of_wt,
volum AS volume,
voleh AS volumeunit
FROM marm
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_marm_db).
SORT lt_marm_db BY material alt_unit.
LOOP AT pt_marm ASSIGNING FIELD-SYMBOL(<fs_marm_pi>).
CLEAR:ls_marm,ls_marmx.
READ TABLE lt_marm_db ASSIGNING FIELD-SYMBOL(<fs_marm_db>) WITH KEY material = <fs_marm_pi>-material alt_unit = <fs_marm_pi>-alt_unit BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_marm_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_marm_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_marm_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marm TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marmx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_marmx IS NOT INITIAL.
ls_marm-function = 'UPD'.
ls_marm-material = <fs_marm_pi>-material.
ls_marm-alt_unit = <fs_marm_pi>-alt_unit.
APPEND ls_marm TO lt_marm.
ls_marmx-function = 'UPD'.
ls_marmx-material = <fs_marm_pi>-material.
ls_marmx-alt_unit = <fs_marm_pi>-alt_unit.
APPEND ls_marmx TO lt_marmx.
pc_head-basic_view = 'X'.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_marm_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_marm_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marm TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_marmx TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_marmx IS NOT INITIAL.
ls_marm-function = 'INS'.
ls_marm-material = <fs_marm_pi>-material.
ls_marm-alt_unit = <fs_marm_pi>-alt_unit.
APPEND ls_marm TO lt_marm.
ls_marmx-function = 'INS'.
ls_marmx-material = <fs_marm_pi>-material.
ls_marmx-alt_unit = <fs_marm_pi>-alt_unit.
APPEND ls_marmx TO lt_marmx.
pc_head-basic_view = 'X'.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MLAN_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MLAN
*& --> LT_MLAN
*& --> LV_MATNR
*&---------------------------------------------------------------------*
FORM frm_fill_mlan_data TABLES pt_mlan STRUCTURE zmms034
lt_mlan STRUCTURE bapie1mlan
USING pi_matnr TYPE mara-matnr.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_mlan TYPE bapie1mlan.
CLEAR:lt_mlan[].
LOOP AT pt_mlan ASSIGNING FIELD-SYMBOL(<fs_mlan>).
PERFORM frm_conversion_matnr_input CHANGING <fs_mlan>-material.
ENDLOOP.
SELECT matnr AS material,
aland AS depcountry,
taxm1 AS taxclass_1
FROM mlan
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_mlan_db).
SORT lt_mlan_db BY material depcountry.
LOOP AT pt_mlan ASSIGNING FIELD-SYMBOL(<fs_mlan_pi>).
CLEAR:ls_mlan.
READ TABLE lt_mlan_db ASSIGNING FIELD-SYMBOL(<fs_mlan_db>) WITH KEY material = <fs_mlan_pi>-material depcountry = <fs_mlan_pi>-depcountry BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mlan_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mlan_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mlan_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mlan TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mlan IS NOT INITIAL.
ls_mlan-function = 'UPD'.
ls_mlan-material = <fs_mlan_pi>-material.
ls_mlan-depcountry = <fs_mlan_pi>-depcountry.
ls_mlan-tax_type_1 = <fs_mlan_pi>-tax_type_1.
APPEND ls_mlan TO lt_mlan.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_mlan_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_mlan_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_mlan TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_mlan IS NOT INITIAL.
ls_mlan-function = 'INS'.
ls_mlan-material = <fs_mlan_pi>-material.
ls_mlan-depcountry = <fs_mlan_pi>-depcountry.
ls_mlan-tax_type_1 = <fs_mlan_pi>-tax_type_1.
APPEND ls_mlan TO lt_mlan.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MAKT_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MAKT
*& --> LT_MAKT
*& --> LV_MATNR
*& <-- LS_HEAD
*&---------------------------------------------------------------------*
FORM frm_fill_makt_data TABLES pt_makt STRUCTURE zmms029
lt_makt STRUCTURE bapie1makt
USING pi_matnr TYPE mara-matnr.
DATA:cl_descr_ref TYPE REF TO cl_abap_structdescr,
cl_elemdescr TYPE REF TO cl_abap_elemdescr.
FIELD-SYMBOLS: <fs_value_pi> TYPE any,
<fs_value_db> TYPE any,
<fs_value_bp> TYPE any,
<fs_type> TYPE any,
<fs_comp> TYPE abap_compdescr.
DATA:ls_makt TYPE bapie1makt.
CLEAR:lt_makt[].
LOOP AT pt_makt ASSIGNING FIELD-SYMBOL(<fs_makt>).
PERFORM frm_conversion_matnr_input CHANGING <fs_makt>-material.
CALL FUNCTION 'CONVERSION_EXIT_ISOLA_INPUT'
EXPORTING
input = <fs_makt>-langu
IMPORTING
output = <fs_makt>-langu
EXCEPTIONS
unknown_language = 1
OTHERS = 2.
ENDLOOP.
SELECT matnr AS material,
spras AS langu,
maktx AS matl_desc
FROM makt
WHERE matnr = @pi_matnr
INTO TABLE @DATA(lt_makt_db).
SORT lt_makt_db BY material langu.
LOOP AT pt_makt ASSIGNING FIELD-SYMBOL(<fs_makt_pi>).
CLEAR:ls_makt.
READ TABLE lt_makt_db ASSIGNING FIELD-SYMBOL(<fs_makt_db>) WITH KEY material = <fs_makt_pi>-material langu = <fs_makt_pi>-langu BINARY SEARCH.
IF sy-subrc = 0.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_makt_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_makt_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_makt_db> TO <fs_value_db>.
IF sy-subrc = 0.
IF <fs_value_pi> NE <fs_value_db>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_makt TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_makt IS NOT INITIAL.
ls_makt-function = 'UPD'.
ls_makt-material = <fs_makt_pi>-material.
ls_makt-langu = <fs_makt_pi>-langu.
APPEND ls_makt TO lt_makt.
ENDIF.
ELSE.
cl_descr_ref ?= cl_abap_typedescr=>describe_by_data( <fs_makt_pi> ).
LOOP AT cl_descr_ref->components ASSIGNING <fs_comp>.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE <fs_makt_pi> TO <fs_value_pi>.
IF sy-subrc = 0.
ASSIGN COMPONENT <fs_comp>-name OF STRUCTURE ls_makt TO <fs_value_bp>.
IF sy-subrc = 0.
<fs_value_bp> = <fs_value_pi>.
ENDIF.
ENDIF.
ENDLOOP.
IF ls_makt IS NOT INITIAL.
ls_makt-function = 'INS'.
ls_makt-material = <fs_makt_pi>-material.
ls_makt-langu = <fs_makt_pi>-langu.
APPEND ls_makt TO lt_makt.
ENDIF.
ENDIF.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILL_MLTX_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& --> PT_MLTX
*& --> LT_MLTX
*&---------------------------------------------------------------------*
FORM frm_fill_mltx_data TABLES pt_mltx STRUCTURE zmms036
lt_mltx STRUCTURE bapie1mltx
USING pi_matnr TYPE mara-matnr.
DATA:lt_tline TYPE TABLE OF tline WITH HEADER LINE.
DATA:ls_mltx TYPE bapie1mltx.
DATA:lv_name TYPE thead-tdname.
CHECK pt_mltx[] IS NOT INITIAL.
lv_name = pi_matnr.
LOOP AT pt_mltx.
CLEAR:ls_mltx.
CALL FUNCTION 'READ_TEXT'
EXPORTING
client = sy-mandt
id = 'GRUN'
language = pt_mltx-langu
name = lv_name
object = 'MATERIAL'
TABLES
lines = lt_tline
EXCEPTIONS
id = 1
language = 2
name = 3
not_found = 4
object = 5
reference_check = 6
wrong_access_to_archive = 7
OTHERS = 8.
IF sy-subrc = 4.
ls_mltx-function = 'INS'.
ELSE.
ls_mltx-function = 'UPD'.
ENDIF.
ls_mltx-material = pi_matnr.
ls_mltx-langu = pt_mltx-langu.
ls_mltx-applobject = 'MATERIAL'.
ls_mltx-text_name = lv_name.
ls_mltx-text_id = 'GRUN'.
ls_mltx-format_col = pt_mltx-format_col.
ls_mltx-text_line = pt_mltx-text_line.
APPEND ls_mltx TO lt_mltx.
ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_CONVERSION_CUNIT_INPUT
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& <-- <FS_MARA>_BASE_UOM
*&---------------------------------------------------------------------*
FORM frm_conversion_cunit_input CHANGING pc_cunit.
CALL FUNCTION 'CONVERSION_EXIT_CUNIT_INPUT'
EXPORTING
input = pc_cunit
language = sy-langu
IMPORTING
output = pc_cunit
EXCEPTIONS
unit_not_found = 1
OTHERS = 2.
ENDFORM.

复制代码

[RFC] 创建和修改物料主数据，自动识别有变动的字段

相关帖子

Ta最近发表

快速回帖