销售订单结算规则-修改

FUNCTION zsdfm036.
*"----------------------------------------------------------------------
*"*"本地接口：
*" IMPORTING
*" VALUE(I_VBELN) TYPE VBELN_VA
*" EXPORTING
*" VALUE(E_MESSAGE) TYPE ZOTS001
*" TABLES
*" T_ITEM STRUCTURE ZSDS187 OPTIONAL
*"----------------------------------------------------------------------
*.COBRA-Buffer (see FM KOBS)
TYPES: BEGIN OF ty_cobra_buf.
INCLUDE STRUCTURE cobra.
TYPES: uflag LIKE dkobr-upd_flag,
END OF ty_cobra_buf.
*.COBRB-Puffer mit Änderungsflag (see FM KOBS)
TYPES: BEGIN OF ty_cobrb_buf.
INCLUDE STRUCTURE cobrb.
TYPES: uflag LIKE dkobr-upd_flag,
END OF ty_cobrb_buf.
DATA: ls_objnr TYPE ionrb,
lt_objnr TYPE TABLE OF ionrb,
ls_cobra TYPE cobra,
lt_cobra TYPE TABLE OF cobra,
ls_cobrb TYPE cobrb,
lt_cobrb TYPE TABLE OF cobrb.
DATA:ls_mem_cobra TYPE ty_cobra_buf.
DATA:lt_mem_cobra TYPE TABLE OF ty_cobra_buf.
DATA:ls_mem_cobrb TYPE ty_cobrb_buf.
DATA:lt_mem_cobrb TYPE TABLE OF ty_cobrb_buf.
DATA:l_mem_cobra TYPE TABLE OF ty_cobra_buf.
DATA:l_mem_cobrb TYPE TABLE OF ty_cobrb_buf.
DATA:lv_objnr TYPE cobra-objnr.
*-->数据转换
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
EXPORTING
input = i_vbeln
IMPORTING
output = i_vbeln.
*-->数据获取
LOOP AT t_item ASSIGNING FIELD-SYMBOL(<fs_item>).
CALL FUNCTION 'CONVERSION_EXIT_OBART_INPUT'
EXPORTING
input = <fs_item>-konty
IMPORTING
output = <fs_item>-konty
EXCEPTIONS
not_found = 1
OTHERS = 2.
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
EXPORTING
input = <fs_item>-hkont
IMPORTING
output = <fs_item>-hkont.
CLEAR:ls_objnr.
ls_objnr-objnr = 'VB' && i_vbeln && <fs_item>-posnr.
APPEND ls_objnr TO lt_objnr.
ENDLOOP.
SELECT vbeln,
posnr
FROM vbap
WHERE vbeln = @i_vbeln
INTO TABLE @DATA(lt_vbap).
lv_objnr = 'VB' && i_vbeln && '%'.
SELECT objnr
FROM cobra
WHERE objnr LIKE @lv_objnr
INTO TABLE @DATA(lt_cobra_db).
SELECT objnr
FROM cobrb
WHERE objnr LIKE @lv_objnr
INTO TABLE @DATA(lt_cobrb_db).
CALL FUNCTION 'K_SRULE_PRE_READ'
TABLES
t_sender_objnr = lt_objnr[]
EXCEPTIONS
wrong_parameters = 1
OTHERS = 2.
CLEAR:lt_mem_cobra,lt_mem_cobrb.
* Fill internal buffer with settlement rules
LOOP AT lt_objnr INTO ls_objnr.
CLEAR:lt_cobra[],lt_cobrb[].
CALL FUNCTION 'K_SETTLEMENT_RULE_GET'
EXPORTING
objnr = ls_objnr-objnr
x_all = ''
TABLES
e_cobra = lt_cobra
e_cobrb = lt_cobrb
EXCEPTIONS
not_found = 1
OTHERS = 2.
IF lt_cobrb[] IS INITIAL. "修改时，新增行项目
"create a new rule header
CALL FUNCTION 'K_SRULE_CREATE'
EXPORTING
i_objnr = ls_objnr-objnr
EXCEPTIONS
rule_already_exists = 1
OTHERS = 2.
CALL FUNCTION 'K_SETTLEMENT_RULE_GET'
EXPORTING
objnr = ls_objnr-objnr
x_all = ''
TABLES
e_cobra = lt_cobra
e_cobrb = lt_cobrb
EXCEPTIONS
not_found = 1
OTHERS = 2.
ENDIF.
"分配结算规则-抬头
LOOP AT lt_cobra INTO ls_cobra.
CLEAR:ls_mem_cobra.
MOVE-CORRESPONDING ls_cobra TO ls_mem_cobra.
READ TABLE lt_vbap TRANSPORTING NO FIELDS WITH KEY posnr = ls_cobra-objnr+12(6).
IF sy-subrc = 0.
READ TABLE lt_cobra_db TRANSPORTING NO FIELDS WITH KEY objnr = ls_cobra-objnr.
IF sy-subrc = 0.
ls_mem_cobra-uflag = 'U'.
ELSE.
ls_mem_cobra-uflag = 'I'.
ENDIF.
ELSE.
READ TABLE lt_cobra_db TRANSPORTING NO FIELDS WITH KEY objnr = ls_cobra-objnr.
IF sy-subrc = 0.
ls_mem_cobra-uflag = 'D'.
ENDIF.
ENDIF.
APPEND ls_mem_cobra TO lt_mem_cobra.
ENDLOOP.
"分配结算规则-行项目
LOOP AT lt_cobrb INTO ls_cobrb.
CLEAR:ls_mem_cobrb.
MOVE-CORRESPONDING ls_cobrb TO ls_mem_cobrb.
READ TABLE t_item WITH KEY posnr = ls_cobrb-objnr+12(6).
IF sy-subrc = 0.
IF t_item-hkont IS NOT INITIAL.
ls_mem_cobrb-hkont = t_item-hkont. "总账科目
ENDIF.
IF t_item-prctr IS NOT INITIAL.
ls_mem_cobrb-prctr = t_item-prctr. "利润中心
ENDIF.
IF t_item-konty IS NOT INITIAL.
ls_mem_cobrb-konty = t_item-konty. "科目分配种类
ENDIF.
ENDIF.
READ TABLE lt_vbap TRANSPORTING NO FIELDS WITH KEY posnr = ls_cobrb-objnr+12(6).
IF sy-subrc = 0.
READ TABLE lt_cobrb_db TRANSPORTING NO FIELDS WITH KEY objnr = ls_cobrb-objnr.
IF sy-subrc = 0.
ls_mem_cobrb-uflag = 'U'.
ELSE.
ls_mem_cobrb-uflag = 'I'.
ls_mem_cobrb-avorg = 'KOAW'. "结算交易
ls_mem_cobrb-srstrat = ''. "审批策略必须为空不然会默认给2
ENDIF.
ELSE.
READ TABLE lt_cobrb_db TRANSPORTING NO FIELDS WITH KEY objnr = ls_cobrb-objnr.
IF sy-subrc = 0.
ls_mem_cobrb-uflag = 'D'.
ENDIF.
ENDIF.
APPEND ls_mem_cobrb TO lt_mem_cobrb.
ENDLOOP.
ENDLOOP.
CHECK e_message-type <> 'E'.
LOOP AT lt_objnr INTO ls_objnr.
CLEAR:l_mem_cobra,l_mem_cobrb.
* Save settlement rule in ABAP-Memory
CALL FUNCTION 'K_SRULE_EXPORT_IMPORT'
EXPORTING
i_mode = 'EX'
EXCEPTIONS
wrong_mode = 1
OTHERS = 2.
* Read ABAP-Memory
IMPORT l_mem_cobra l_mem_cobrb FROM MEMORY ID 'K_SRULE'."内存变量不能修改
"ABAP内存赋值
CLEAR:l_mem_cobra,l_mem_cobrb.
LOOP AT lt_mem_cobra INTO ls_mem_cobra WHERE objnr = ls_objnr-objnr.
APPEND ls_mem_cobra TO l_mem_cobra.
ENDLOOP.
LOOP AT lt_mem_cobrb INTO ls_mem_cobrb WHERE objnr = ls_objnr-objnr.
APPEND ls_mem_cobrb TO l_mem_cobrb.
ENDLOOP.
* Clear internal buffer
CALL FUNCTION 'K_SETTLEMENT_RULE_REFRESH'
EXPORTING
objnr = ls_objnr-objnr.
* Fill ABAP-Memory with new rules
EXPORT l_mem_cobra l_mem_cobrb TO MEMORY ID 'K_SRULE'.
* Fill internal buffer with new rules
CALL FUNCTION 'K_SRULE_EXPORT_IMPORT'
EXPORTING
i_mode = 'IM'
EXCEPTIONS
wrong_mode = 1
OTHERS = 2.
* Save new rules
CALL FUNCTION 'K_SETTLEMENT_RULE_SAVE'
EXPORTING
Dialog = 'X'
objnr = ls_objnr-objnr
i_status_update = ' '
EXCEPTIONS
no_rule_for_objnr = 1
OTHERS = 2.
IF sy-subrc = 0.
COMMIT WORK.
e_message-type = 'S'.
e_message-message = '结算规则更新成功'.
ELSE.
ROLLBACK WORK.
e_message-type = 'E'.
e_message-message = '结算规则更新失败'.
EXIT.
ENDIF.
ENDLOOP.
ENDFUNCTION.

复制代码

[RFC] 销售订单结算规则-修改

Ta最近发表

快速回帖