ABAP中面向对象的多态性

“多态性”一词最早用于生物学，指同一种族的生物体具有不同的特性。在面向对象的程序设计理论中，多态性的定义是：同一操作作用于不同的类的实例，将产生不同的执行结果，即不同类的对象收到相同的消息时，得到不同的结果。多态是面向对象程序设计的重要特征之一，是扩展性在“继承”之后的又一重大表现 。对象根据所接受的消息而做出动作，同样的消息被不同的对象接受时可能导致完全不同的行为，这种现象称为多态性。

学习类的多态性之前，需了解：ABAP面向对象中类的层次结构

示例：

1. REPORT yleon_002.
   
2. 
   
3. TYPE-POOLS icon.
   
4. 
   
5. INCLUDE yleon_002_a.
   
6. 
   
7. DATA: r_plane     TYPE REF TO lcl_airplane,
   
8.       r_cargo     TYPE REF TO lcl_cargo_plane,
   
9.       r_passenger TYPE REF TO lcl_passenger_plane,
   
10.       plane_list  TYPE TABLE OF REF TO lcl_airplane.
    
11. 
    
12. START-OF-SELECTION.
    
13.   lcl_airplane=>display_n_o_airplanes( ).
    
14.   CREATE OBJECT r_passenger
    
15.     EXPORTING
    
16.       im_name      = 'LH BERLIN'
    
17.       im_planetype = '747-400'
    
18.       im_seats     = 345.
    
19.   APPEND r_passenger TO plane_list.
    
20.   CREATE OBJECT r_cargo
    
21.     EXPORTING
    
22.       im_name      = 'US HErcules'
    
23.       im_planetype = '747-500'
    
24.       im_cargo     = 533.
    
25.   APPEND r_cargo TO plane_list.
    
26.   LOOP AT plane_list INTO r_plane.
    
27.     r_plane->display_attributes( ).
    
28.   ENDLOOP.
    
29.   lcl_airplane=>display_n_o_airplanes( ).

复制代码

1. *&---------------------------------------------------------------------*
   
2. *&  包含                YLEON_002_A
   
3. *&---------------------------------------------------------------------*
   
4. CLASS lcl_airplane DEFINITION.
   
5.   PUBLIC SECTION.
   
6.     CONSTANTS: pos_1 TYPE i VALUE 30.
   
7.     METHODS: constructor IMPORTING im_name      TYPE string
   
8.                                    im_planetype TYPE saplane-planetype,
   
9.       display_attributes.
   
10.     CLASS-METHODS: display_n_o_airplanes.
    
11. 
    
12.   PRIVATE SECTION.
    
13.     METHODS: get_technical_attributes
    
14.       IMPORTING im_type    TYPE saplane-planetype
    
15.       EXPORTING ex_weight  TYPE s_plan_wei
    
16.                 ex_tankcap TYPE s_capacity.
    
17.     DATA: name      TYPE string,
    
18.           planetype TYPE saplane-planetype.
    
19.     CLASS-DATA: n_o_airplanes TYPE i.
    
20. ENDCLASS. "lcl_airplane DEFINITION
    
21. 
    
22. CLASS lcl_airplane IMPLEMENTATION.
    
23.   METHOD constructor.
    
24.     name = im_name.
    
25.     planetype = im_planetype.
    
26.     n_o_airplanes = n_o_airplanes + 1.
    
27.   ENDMETHOD. "constructor
    
28.   METHOD display_attributes.
    
29.     DATA: weight TYPE saplane-weight,
    
30.           cap    TYPE saplane-tankcap.
    
31.     WRITE: / icon_ws_plane AS ICON,
    
32.     / 'Name of airplane'(001), AT pos_1 name,
    
33.     / 'Airplane type: '(002), AT pos_1 planetype.
    
34.     get_technical_attributes( EXPORTING im_type = planetype
    
35.                               IMPORTING ex_weight = weight
    
36.                               ex_tankcap = cap ).
    
37.     WRITE: / 'Weight:'(003), weight,
    
38.     'Tank capacity:'(004), cap.
    
39.   ENDMETHOD. "display_attributes
    
40.   METHOD display_n_o_airplanes.
    
41.     WRITE: /, / 'Number of airplanes: '(ca1),
    
42.     AT pos_1 n_o_airplanes LEFT-JUSTIFIED, /.
    
43.   ENDMETHOD. "display_n_o_airplanes
    
44.   METHOD get_technical_attributes.
    
45.     SELECT SINGLE weight tankcap FROM saplane
    
46.     INTO (ex_weight, ex_tankcap)
    
47.     WHERE planetype = im_type.
    
48.     IF sy-subrc <> 0.
    
49.       ex_weight = 100000.
    
50.       ex_tankcap = 10000.
    
51.     ENDIF.
    
52.   ENDMETHOD. "get_technical_attributes
    
53. ENDCLASS. "lcl_airplane IMPLEMENTATION
    
54. 
    
55. CLASS lcl_cargo_plane DEFINITION INHERITING FROM lcl_airplane.
    
56.   PUBLIC SECTION.
    
57.     METHODS: constructor IMPORTING im_name      TYPE string
    
58.                                    im_planetype TYPE saplane-planetype
    
59.                                    im_cargo     TYPE scplane-cargomax.
    
60.     METHODS: display_attributes REDEFINITION.
    
61.     METHODS: get_cargo RETURNING VALUE(re_cargo) TYPE scplane-cargomax.
    
62.   PRIVATE SECTION.
    
63.     DATA: max_cargo TYPE scplane-cargomax.
    
64. ENDCLASS. "lcl_cargo_plane DEFINITION
    
65. CLASS lcl_cargo_plane IMPLEMENTATION.
    
66.   METHOD constructor.
    
67.     CALL METHOD super->constructor( im_name = im_name im_planetype = im_planetype ).
    
68.     max_cargo = im_cargo.
    
69.   ENDMETHOD. "constructor
    
70.   METHOD display_attributes.
    
71.     super->display_attributes( ).
    
72.     WRITE: / 'Max Cargo = ', max_cargo.
    
73.     ULINE.
    
74.   ENDMETHOD. "display_attributes
    
75.   METHOD get_cargo.
    
76.     re_cargo = max_cargo.
    
77.   ENDMETHOD. "get_cargo
    
78. ENDCLASS. "lcl_cargo_plane IMPLEMENTATION
    
79. CLASS lcl_passenger_plane DEFINITION INHERITING FROM lcl_airplane..
    
80.   PUBLIC SECTION.
    
81.     METHODS: constructor IMPORTING im_name      TYPE string
    
82.                                    im_planetype TYPE saplane-planetype
    
83.                                    im_seats     TYPE sflight-seatsmax.
    
84.     METHODS: display_attributes REDEFINITION.
    
85.   PRIVATE SECTION.
    
86.     DATA: max_seats TYPE sflight-seatsmax.
    
87. ENDCLASS. "lcl_passenger_plane DEFINITION
    
88. 
    
89. CLASS lcl_passenger_plane IMPLEMENTATION.
    
90.   METHOD constructor.
    
91.     CALL METHOD super->constructor(
    
92.       EXPORTING
    
93.         im_name      = im_name
    
94.         im_planetype = im_planetype ).
    
95.     max_seats = im_seats.
    
96.   ENDMETHOD. "constructor
    
97.   METHOD display_attributes.
    
98.     super->display_attributes( ).
    
99.     WRITE: / 'Max Seats = ', max_seats.
    
100.     ULINE.
     
101.   ENDMETHOD. "display_attributes
     
102. ENDCLASS. "lcl_passenger_plane IMPLEMENTATION

复制代码

执行结果：