VA02修改销售订单BAPI_SALESORDER_CHANGE

程序代码：

FUNCTION zsdfm001_update.
*"----------------------------------------------------------------------
*"*"本地接口：
*" IMPORTING
*" VALUE(I_HEADER) TYPE ZSDS106 OPTIONAL
*" EXPORTING
*" VALUE(E_MESSAGE) TYPE ZOTS001
*" VALUE(E_STONR) TYPE J_STONR
*" TABLES
*" T_VBPA STRUCTURE ZSDS109 OPTIONAL
*" T_ITEM STRUCTURE ZSDS107 OPTIONAL
*" T_KONV STRUCTURE ZSDS108 OPTIONAL
*" T_KONVT STRUCTURE ZSDS108 OPTIONAL
*" T_COBRB STRUCTURE ZSDS187 OPTIONAL
*"----------------------------------------------------------------------
DATA:ls_logic_switch TYPE bapisdls.
DATA:gwa_bapisdh1 TYPE bapisdhd1. "抬头
DATA:gwa_bapisdh1x TYPE bapisdhd1x. "抬头确认
DATA:gwa_partnerchanges TYPE bapiparnrc. "合作伙伴更改
DATA:git_partnerchanges TYPE TABLE OF bapiparnrc.
DATA:gwa_bapisditm TYPE bapisditm. "行项目
DATA:git_bapisditm TYPE TABLE OF bapisditm.
DATA:gwa_bapisditmx TYPE bapisditmx. "行项目确认
DATA:git_bapisditmx TYPE TABLE OF bapisditmx.
DATA:gwa_bapischdl TYPE bapischdl. "计划行
DATA:git_bapischdl TYPE TABLE OF bapischdl. "计划行
DATA:gwa_bapischdlx TYPE bapischdlx. "计划行
DATA:git_bapischdlx TYPE TABLE OF bapischdlx. "计划行
DATA:gwa_bapicond TYPE bapicond. "价格
DATA:git_bapicond TYPE TABLE OF bapicond.
DATA:gwa_bapicondx TYPE bapicondx.
DATA:git_bapicondx TYPE TABLE OF bapicondx.
DATA:git_order_text TYPE TABLE OF bapisdtext."长文本
DATA:gwa_bapiret2 TYPE bapiret2.
DATA:git_bapiret2 TYPE TABLE OF bapiret2.
DATA:lt_konv_t TYPE TABLE OF zsds108.
DATA:ls_item TYPE zsds107.
DATA:ls_konv TYPE zsds108.
DATA:lv_stonr TYPE j_stonr.
DATA:lv_objnr TYPE jsto-objnr.
DATA:lv_kALVg TYPE tvak-kalvg.
DATA:lv_kalks TYPE knvv-kalks.
DATA:lv_kalsm TYPE t683s-kalsm.
DATA:lv_kunnr TYPE vbak-kunnr.
DATA ls_zots001 TYPE zots001.
CHECK i_header-vbeln IS NOT INITIAL.
PERFORM frm_inputsap_data CHANGING i_header-vbeln.
lt_konv_t[] = t_konv[].
APPEND LINES OF t_konvt TO lt_konv_t.
LOOP AT lt_konv_t ASSIGNING FIELD-SYMBOL(<fs_konv_t>).
IF <fs_konv_t>-kbetr IS NOT INITIAL AND <fs_konv_t>-waers IS INITIAL.
e_message-type = 'E'.
e_message-message = '定价条件' && t_konv-kschl && '缺少货币单位'.
EXIT.
ENDIF.
ENDLOOP.
READ TABLE lt_konv_t TRANSPORTING NO FIELDS WITH KEY mark = 'D'.
IF sy-subrc = 0.
READ TABLE lt_konv_t TRANSPORTING NO FIELDS WITH KEY mark = 'I'.
IF sy-subrc = 0.
e_message-type = 'E'.
e_message-message = '价格中新增(I)和删除(D)不能同时操作'.
EXIT.
ENDIF.
ENDIF.
CHECK e_message-type NE 'E'.
*-->抬头
gwa_bapisdh1-purch_no_c = i_header-bstkd."采购订单编号
CONCATENATE i_header-date+0(4) i_header-date+5(2) i_header-date+8(2) INTO gwa_bapisdh1-purch_date."采购订单日期
gwa_bapisdh1-pmnttrms = i_header-zterm."付款条件
gwa_bapisdh1-ord_reason = i_header-augru."订单原因
* gwa_bapisdh1-costcenter = i_header-kostl."成本中心
gwa_bapisdh1-mn_invoice = i_header-mrnkz."人工发票维护
gwa_bapisdh1-collect_no = i_header-submi."汇总数
gwa_bapisdh1-po_meth_s = i_header-bsark_e."采购订单类型
gwa_bapisdh1-purch_no_s = i_header-bstkd_e.
gwa_bapisdh1-po_supplem = i_header-bstzd.
gwa_bapisdh1-sales_grp = i_header-vkgrp."销售组
gwa_bapisdh1-sales_off = i_header-vkbur."销售办公室
gwa_bapisdh1-cust_group = i_header-kdgrp."客户组
gwa_bapisdh1-cust_grp1 = i_header-kvgr1."客户组1
gwa_bapisdh1-cust_grp3 = i_header-kvgr3."客户组3
gwa_bapisdh1-name = i_header-name ."来源单号
gwa_bapisdh1-ship_type = i_header-vsart.
gwa_bapisdh1-ref_1_s = i_header-ihrez_e.
gwa_bapisdh1-ref_1 = i_header-ihrez."您的参考
gwa_bapisdh1-taxdst_cty = i_header-stceg_l."目的地国
gwa_bapisdh1-currency = i_header-waers."币种
gwa_bapisdh1-version = i_header-vsnmr_v."版本
CLEAR gwa_bapisdh1x.
gwa_bapisdh1x-updateflag = 'U'."更新标识
gwa_bapisdh1x-purch_no_c = 'X'."采购订单编号
gwa_bapisdh1-compl_dlv = i_header-compl_dlv."全部交货
gwa_bapisdh1x-compl_dlv = 'X'."全部交货
gwa_bapisdh1x-pmnttrms = 'X'."付款条件
gwa_bapisdh1x-ord_reason = 'X'."订单原因
gwa_bapisdh1x-purch_no_s = 'X'.
gwa_bapisdh1x-po_meth_s = 'X'."采购订单类型
gwa_bapisdh1x-po_supplem = 'X'."采购单编号补充
gwa_bapisdh1x-sales_grp = 'X'."销售组
gwa_bapisdh1x-sales_off = 'X'."销售办公室
gwa_bapisdh1x-ship_type = 'X'.
gwa_bapisdh1x-cust_group = 'X'."客户组
gwa_bapisdh1x-cust_grp1 = 'X'."客户组1
gwa_bapisdh1x-cust_grp3 = 'X'."客户组3
gwa_bapisdh1-ref_1_s = 'X'.
gwa_bapisdh1x-ref_1 = 'X'."您的参考
gwa_bapisdh1x-mn_invoice = 'X'.
gwa_bapisdh1x-collect_no = 'X'.
gwa_bapisdh1x-version = 'X'."版本
IF i_header-waers IS NOT INITIAL.
gwa_bapisdh1x-currency = 'X'."币种
ENDIF.
IF i_header-date IS NOT INITIAL.
gwa_bapisdh1x-purch_date = 'X'."采购订单日期
ENDIF.
IF gwa_bapisdh1-name IS NOT INITIAL.
gwa_bapisdh1x-name = 'X'.
ENDIF.
* IF gwa_bapisdh1-costcenter IS NOT INITIAL.
* gwa_bapisdh1x-costcenter = 'X'.
* ENDIF.
IF gwa_bapisdh1-taxdst_cty IS NOT INITIAL.
gwa_bapisdh1x-taxdst_cty = 'X'.
ENDIF.
SELECT vbeln,
posnr,
parvw,
kunnr,
lifnr,
pernr
FROM vbpa
WHERE vbeln = @i_header-vbeln AND posnr = '000000'
INTO TABLE @DATA(lt_vbpa).
*-->合作伙伴
LOOP AT t_vbpa.
CLEAR:gwa_partnerchanges.
PERFORM frm_inputsap_data CHANGING t_vbpa-vbeln.
gwa_partnerchanges-document = t_vbpa-vbeln.
gwa_partnerchanges-itm_number = '000000'.
gwa_partnerchanges-updateflag = t_vbpa-mark.
gwa_partnerchanges-partn_role = t_vbpa-parvw.
READ TABLE lt_vbpa INTO DATA(ls_vbpa) WITH KEY parvw = t_vbpa-parvw.
IF sy-subrc = 0.
IF ls_vbpa-pernr IS NOT INITIAL.
gwa_partnerchanges-p_numb_old = ls_vbpa-pernr.
ELSE.
gwa_partnerchanges-p_numb_old = ls_vbpa-kunnr.
ENDIF.
ENDIF.
gwa_partnerchanges-p_numb_new = t_vbpa-kunn2.
APPEND gwa_partnerchanges TO git_partnerchanges.
ENDLOOP.
*-->抬头长文本
IF i_header-head1 IS NOT INITIAL.
PERFORM frm_order_text TABLES git_order_text USING 'Z001' i_header-vbeln space i_header-head1.
ENDIF.
IF i_header-head2 IS NOT INITIAL.
PERFORM frm_order_text TABLES git_order_text USING 'Z002' i_header-vbeln space i_header-head2.
ENDIF.
*-->行项目
SELECT vbeln,
posnr,
etenr,
edatu
FROM vbep
WHERE vbeln = @i_header-vbeln
INTO TABLE @DATA(lt_vbep).
DELETE t_item WHERE pstyv = 'ZTTN'.
SORT lt_vbep BY vbeln posnr etenr.
LOOP AT t_item INTO ls_item.
PERFORM frm_inputsap_data CHANGING ls_item-vbeln.
PERFORM frm_chang_in CHANGING ls_item-matnr.
PERFORM frm_inputsap_data CHANGING ls_item-posnr.
PERFORM frm_inputsap_data CHANGING ls_item-posnv.
PERFORM frm_inputsap_data CHANGING ls_item-uepos.
PERFORM frm_input_unit CHANGING ls_item-vrkme. "销售单位
CLEAR gwa_bapisditm.
gwa_bapisditm-itm_number = ls_item-posnr."行项目号
gwa_bapisditm-material = ls_item-matnr."物料编码
* gwa_bapisditm-target_qty = ls_item-kwmeng."数量
gwa_bapisditm-cust_mat35 = ls_item-kdmat."客户物料号
gwa_bapisditm-hg_lv_item = ls_item-uepos."上层项目
gwa_bapisditm-reason_rej = ls_item-abgru."拒绝原因
IF ls_item-werks IS NOT INITIAL. "工厂
gwa_bapisditm-plant = ls_item-werks.
ELSE.
gwa_bapisditm-plant = i_header-werks.
ENDIF.
IF ls_item-lgort IS NOT INITIAL.
gwa_bapisditm-store_loc = ls_item-lgort."库位
ENDIF.
IF ls_item-pstyv IS NOT INITIAL.
gwa_bapisditm-item_categ = ls_item-pstyv."项目类别
ENDIF.
IF ls_item-vrkme IS NOT INITIAL.
gwa_bapisditm-sales_unit = ls_item-vrkme.
ENDIF.
APPEND gwa_bapisditm TO git_bapisditm.
CLEAR gwa_bapisditmx.
gwa_bapisditmx-itm_number = ls_item-posnr. "行项目号
gwa_bapisditmx-updateflag = ls_item-mark .
gwa_bapisditmx-material = 'X'. "物料编码
gwa_bapisditmx-cust_mat35 = 'X'. "客户物料号
gwa_bapisditmx-reason_rej = 'X'. "拒绝原因
IF ls_item-uepos IS NOT INITIAL.
gwa_bapisditmx-hg_lv_item = 'X'. "上层项目
ENDIF.
IF gwa_bapisditm-plant IS NOT INITIAL. "工厂
gwa_bapisditmx-plant = 'X'.
ENDIF.
IF gwa_bapisditm-store_loc IS NOT INITIAL. "库位
gwa_bapisditmx-store_loc = 'X'.
ENDIF .
IF gwa_bapisditm-item_categ IS NOT INITIAL. "项目类别
gwa_bapisditmx-item_categ = 'X'.
ENDIF.
IF ls_item-vrkme IS NOT INITIAL.
gwa_bapisditmx-sales_unit = 'X'.
ENDIF.
APPEND gwa_bapisditmx TO git_bapisditmx.
**-->计划行.
gwa_bapischdl-itm_number = ls_item-posnr.
gwa_bapischdl-sched_line = 1.
READ TABLE lt_vbep ASSIGNING FIELD-SYMBOL(<fs_vbep>) WITH KEY posnr = ls_item-posnr.
IF sy-subrc = 0.
gwa_bapischdl-req_date = <fs_vbep>-edatu.
ELSE.
IF ls_item-date IS NOT INITIAL.
CONCATENATE ls_item-date+0(4) ls_item-date+5(2) ls_item-date+8(2) INTO gwa_bapischdl-req_date.
ELSEIF gwa_bapisdh1-purch_date IS NOT INITIAL.
gwa_bapischdl-req_date = gwa_bapisdh1-purch_date.
ELSE.
gwa_bapischdl-req_date = sy-datum .
ENDIF.
ENDIF.
gwa_bapischdl-req_qty = ls_item-kwmeng.
APPEND gwa_bapischdl TO git_bapischdl.
CLEAR gwa_bapischdlx.
gwa_bapischdlx-itm_number = ls_item-posnr. "行项目号
gwa_bapischdlx-sched_line = 1.
gwa_bapischdlx-updateflag = ls_item-mark. " U,D,I
gwa_bapischdlx-req_date = 'X'. "首个交货日期（计划行）
gwa_bapischdlx-req_qty = 'X'. "数量
APPEND gwa_bapischdlx TO git_bapischdlx.
*-->行项目长文本
IF ls_item-beiz1 IS NOT INITIAL.
PERFORM frm_order_text TABLES git_order_text USING 'Z001' ls_item-vbeln ls_item-posnr ls_item-beiz1.
ENDIF.
ENDLOOP.
*-->定价
DATA:lv_knumv TYPE vbak-knumv,
lv_first TYPE char1,
lv_cond_st_no TYPE bapicond-cond_st_no.
DATA:BEGIN OF lt_konv OCCURS 0,
knumv TYPE konv-knumv,
kposn TYPE konv-kposn,
stunr TYPE konv-stunr,
zaehk TYPE konv-zaehk,
kschl TYPE konv-kschl,
END OF lt_konv.
IF t_konvt[] IS NOT INITIAL.
READ TABLE t_konv TRANSPORTING NO FIELDS WITH KEY kschl = 'ZZ01'.
IF sy-subrc = 0.
DELETE t_konvt WHERE kschl = 'ZZ01'.
ENDIF.
ENDIF.
APPEND LINES OF t_konvt TO t_konv.
DELETE t_konv WHERE kschl = 'ZA00'. "ZA00 国内销售折扣自动计算出来不需要传入
* DELETE t_konv WHERE mark = 'U' AND kbetr IS INITIAL. "价格为零不需要更新
SELECT SINGLE knumv INTO lv_knumv FROM vbak WHERE vbeln = i_header-vbeln.
IF sy-subrc = 0.
SELECT knumv
kposn
stunr
zaehk
kschl
INTO TABLE lt_konv
FROM v_konv_cds
WHERE knumv = lv_knumv.
SORT lt_konv BY knumv kposn stunr zaehk.
ENDIF.
READ TABLE t_vbpa ASSIGNING FIELD-SYMBOL(<fs_vbpa>) WITH KEY parvw = 'AG'. "售达方
IF sy-subrc = 0.
lv_kunnr = <fs_vbpa>-kunn2.
ENDIF.
SELECT SINGLE kalvg INTO lv_kalvg FROM tvak WHERE auart = i_header-auart.
SELECT SINGLE kalks INTO lv_kalks FROM knvv WHERE kunnr = lv_kunnr AND vkorg = i_header-vkorg AND vtweg = i_header-vtweg AND spart = i_header-spart.
SELECT SINGLE kalsm INTO lv_kalsm FROM t683v WHERE vkorg = i_header-vkorg AND vtweg = i_header-vtweg AND spart = i_header-spart AND kalvg = lv_kalvg AND kalks = lv_kalks.
LOOP AT t_konv INTO ls_konv.
PERFORM frm_inputsap_data CHANGING ls_konv-posnr.
CLEAR:gwa_bapicond,gwa_bapicondx.
READ TABLE lt_konv WITH KEY kposn = ls_konv-posnr kschl = ls_konv-kschl.
IF sy-subrc = 0.
CASE ls_konv-mark.
WHEN 'U'.
gwa_bapicond-itm_number = lt_konv-kposn. "行项目号
gwa_bapicond-cond_st_no = lt_konv-stunr. "步骤编号
gwa_bapicond-cond_count = lt_konv-zaehk. "条件计数器
gwa_bapicond-cond_type = lt_konv-kschl. "定价条件
gwa_bapicond-cond_value = ls_konv-kbetr.
gwa_bapicond-currency = ls_konv-waers. "货币码
APPEND gwa_bapicond TO git_bapicond.
gwa_bapicondx-itm_number = ls_konv-posnr. "行项目号
gwa_bapicondx-cond_st_no = lt_konv-stunr. "步骤编号
gwa_bapicondx-cond_count = lt_konv-zaehk. "条件计数器
gwa_bapicondx-cond_type = lt_konv-kschl. "定价条件
gwa_bapicondx-updateflag = ls_konv-mark. "I \U \D
gwa_bapicondx-cond_value = 'X'.
IF ls_konv-waers IS NOT INITIAL.
gwa_bapicondx-currency = 'X'.
ENDIF.
APPEND gwa_bapicondx TO git_bapicondx.
WHEN 'D'.
gwa_bapicond-itm_number = lt_konv-kposn. "行项目号
gwa_bapicond-cond_st_no = lt_konv-stunr. "步骤编号
gwa_bapicond-cond_count = lt_konv-zaehk. "条件计数器
gwa_bapicond-cond_type = lt_konv-kschl. "定价条件
APPEND gwa_bapicond TO git_bapicond.
gwa_bapicondx-itm_number = ls_konv-posnr. "行项目号
gwa_bapicondx-cond_st_no = lt_konv-stunr. "步骤编号
gwa_bapicondx-cond_count = lt_konv-zaehk. "条件计数器
gwa_bapicondx-cond_type = lt_konv-kschl. "定价条件
gwa_bapicondx-updateflag = ls_konv-mark. "I \U \D
APPEND gwa_bapicondx TO git_bapicondx.
ENDCASE.
ELSEIF ls_konv-mark = 'I'.
SELECT SINGLE stunr INTO lv_cond_st_no FROM t683s WHERE kvewe = 'A' AND kappl = 'V' AND kalsm = lv_kalsm AND kschl = ls_konv-kschl.
IF sy-subrc = 0.
gwa_bapicond-itm_number = ls_konv-posnr. "行项目号
gwa_bapicond-cond_st_no = lv_cond_st_no. "步骤编号
gwa_bapicond-cond_count = '01'. "条件计数器
gwa_bapicond-cond_type = ls_konv-kschl. "定价条件
gwa_bapicond-cond_value = ls_konv-kbetr.
gwa_bapicond-currency = ls_konv-waers. "货币码
APPEND gwa_bapicond TO git_bapicond.
gwa_bapicondx-itm_number = ls_konv-posnr. "行项目号
gwa_bapicondx-cond_st_no = lv_cond_st_no."步骤编号
gwa_bapicondx-cond_count = '01'. "条件计数器
gwa_bapicondx-cond_type = ls_konv-kschl. "定价条件
gwa_bapicondx-updateflag = 'U'. "I \U \D
gwa_bapicondx-cond_value = 'X'.
IF ls_konv-waers IS NOT INITIAL.
gwa_bapicondx-currency = 'X'.
ENDIF.
APPEND gwa_bapicondx TO git_bapicondx.
ELSEIF ls_konv-kbetr IS NOT INITIAL.
e_message-type = 'E'.
e_message-message = lv_kalsm && '定价过程中没有定价类型' && ls_konv-kschl.
EXIT.
ENDIF.
ENDIF.
ENDLOOP.
READ TABLE t_konv TRANSPORTING NO FIELDS WITH KEY mark = 'D'.
IF sy-subrc = 0.
ls_logic_switch-cond_handl = 'X'. "开启，能删除行项目，但是不能新增行项目，建议不开启，删除使用作废行项目替代
ENDIF.
CHECK e_message-type NE 'E'.
*更改计划行类别增强
lv_stonr = i_header-stonr.
EXPORT lv_stonr TO MEMORY ID 'ABAP_STONR'. "10/20/30/40/50
CALL FUNCTION 'SD_SALESDOCUMENT_CHANGE'
EXPORTING
salesdocument = i_header-vbeln
logic_switch = ls_logic_switch
order_header_in = gwa_bapisdh1
order_header_inx = gwa_bapisdh1x
call_from_bapi = 'X' "开启长文本
TABLES
return = git_bapiret2
item_in = git_bapisditm
item_inx = git_bapisditmx
schedule_in = git_bapischdl
schedule_inx = git_bapischdlx
partnerchanges = git_partnerchanges
sales_text = git_order_text
conditions_in = git_bapicond
conditions_inx = git_bapicondx
EXCEPTIONS
incov_not_in_item = 1
OTHERS = 2.
LOOP AT git_bapiret2 INTO gwa_bapiret2 WHERE type CA 'AEX'.
IF e_message-message IS INITIAL.
e_message-message = gwa_bapiret2-message.
ELSE.
e_message-message = e_message-message && '/' && gwa_bapiret2-message.
ENDIF.
ENDLOOP.
IF sy-subrc = 0.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
e_message-type = 'E'.
ELSE.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
wait = 'X'.
e_message-type = 'S'.
e_message-message = '订单修改成功'.
*-------------------------by kevin 20221124 服务类订单修改结算规则 begin-------------------------------------------*
IF t_cobrb[] IS NOT INITIAL.
CALL FUNCTION 'ZSDFM036'
EXPORTING
i_vbeln = i_header-vbeln
IMPORTING
e_message = ls_zots001
TABLES
t_item = t_cobrb[].
IF ls_zots001-type = 'E'.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
e_message = ls_zots001.
RETURN.
ENDIF.
ENDIF.
*-------------------------BY KEVIN 20221124 服务类订单修改结算规则 ENDIN-------------------------------------------*
*获取审核后的状态
CONCATENATE 'VB' i_header-vbeln '000000' INTO lv_objnr.
CALL FUNCTION 'STATUS_READ'
EXPORTING
client = sy-mandt
objnr = lv_objnr
IMPORTING
stonr = e_stonr
EXCEPTIONS
object_not_found = 1
OTHERS = 2.
ENDIF.
ENDFUNCTION.

复制代码

[BAPI] VA02修改销售订单BAPI_SALESORDER_CHANGE

相关帖子

Ta最近发表

快速回帖