设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

批量修改生产订单状态

Twilight发表于 2026-03-12 16:59Twilight 最后回复于 2026-03-12 16:59 [复制链接] 13 0

标准程序：PPARCHP1 生产订单：设置删除标记和删除标识
取消删除生产订单，试一试 ORDER_CHANGE_FOR_ACTIVITY
  1.   REPORT zppr004 MESSAGE-ID 00.

  3. *&---------------------------------------------------------------------*
  4. *& INCLUDE
  5. *&---------------------------------------------------------------------*
  6.   INCLUDE zppr004_top.
  7.   INCLUDE zppr004_selscr.
  8.   INCLUDE zppr004_form.
  9. *&---------------------------------------------------------------------*
  10. *& 初始化处理
  11. *&---------------------------------------------------------------------*
  12.   INITIALIZATION.

  14. *&---------------------------------------------------------------------*
  15. *& 选择屏幕控制
  16. *&---------------------------------------------------------------------*
  17.   AT SELECTION-SCREEN OUTPUT.

  19. *----------------------------------------------------------------------*
  20. *         AT SELECTION-SCREEN ON VALUE-REQUEST                         *
  21. *----------------------------------------------------------------------*
  22. *  AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.

  24. *&---------------------------------------------------------------------*
  25. *& 参数输入检查
  26. *&---------------------------------------------------------------------*
  27.   AT SELECTION-SCREEN.
  28. *&---------------------------------------------------------------------*
  29. *& 程序开始处理
  30. *&---------------------------------------------------------------------*
  31.   START-OF-SELECTION.
  32.     IF s_aufnr[] IS INITIAL.
  33.       MESSAGE '生产订单必填' TYPE 'E'.
  34.     ENDIF.
  35.     PERFORM frm_data_check.
  36. *&---------------------------------------------------------------------*
  37. *& 程序结束处理
  38. *&---------------------------------------------------------------------*
  39.   END-OF-SELECTION.
  40.     PERFORM frm_show_ALV.
复制代码
  1. *&---------------------------------------------------------------------*
  2. *& 包含               ZPPR004_TOP
  3. *&---------------------------------------------------------------------*
  4. ****************上载相关**********************************
  5. TABLES:aufk."屏幕表
  6. TYPE-POOLS:slis,truxs,icon.
  7. DATA functxt TYPE smp_dyntxt.
  8. ****************上载相关**********************************

  10. *****************定义结构************************************
  11. TYPES:BEGIN OF ty_alv,
  12.         aufnr    TYPE aufk-aufnr,
  13.         bukrs    TYPE aufk-bukrs,
  14.         werks    TYPE aufk-werks,
  15.         erdat    TYPE aufk-erdat,
  16.         flag(1),
  17.         zid      TYPE icon-id,         " 信号
  18.         zmessage TYPE zmmt004-zmessage, " 提示文本
  19.       END OF ty_alv.

  21. *****************定义结构************************************
  22. DATA:gt_alv TYPE TABLE OF ty_alv WITH HEADER LINE.
复制代码
  1. *&---------------------------------------------------------------------*
  2. *& 包含               ZPPR004_SELSCR
  3. *&---------------------------------------------------------------------*
  4. SELECTION-SCREEN FUNCTION KEY 1.
  5. SELECTION-SCREEN BEGIN OF BLOCK blk01 WITH FRAME TITLE TEXT-001.
  6. SELECT-OPTIONS:s_aufnr FOR aufk-aufnr.
  7. SELECTION-SCREEN END OF BLOCK blk01.
  8. SELECTION-SCREEN BEGIN OF BLOCK blk02 WITH FRAME TITLE TEXT-002.
  9. PARAMETERS p_del RADIOBUTTON GROUP typ USER-COMMAND sele DEFAULT 'X'."设置删除
  10. PARAMETERS p_cal RADIOBUTTON GROUP typ."取消删除
  11. SELECTION-SCREEN END OF BLOCK blk02.
复制代码
  1. *&---------------------------------------------------------------------*
  2. *&  包含                ZPPR004_FORM
  3. *&---------------------------------------------------------------------*
  4. *&---------------------------------------------------------------------*
  5. *&      Form  FRM_DATA_CHECK
  6. *&---------------------------------------------------------------------*
  7. *       text
  8. *----------------------------------------------------------------------*
  9. *  -->  p1        text
  10. *  <--  p2        text
  11. *----------------------------------------------------------------------*
  12. FORM frm_data_check .

  14.   SELECT aufk~aufnr,
  15.          aufk~bukrs,
  16.          aufk~werks,
  17.          aufk~erdat,
  18.          aufk~objnr
  19.     FROM aufk
  20.     WHERE aufk~autyp = '10'
  21.       AND aufk~aufnr IN @s_aufnr
  22.     INTO TABLE @DATA(lt_aufk).


  25.   SORT lt_aufk BY aufnr.
  26.   LOOP AT lt_aufk ASSIGNING FIELD-SYMBOL(<fs_aufk>).
  27.     CLEAR:gt_alv.
  28.     gt_alv-aufnr = <fs_aufk>-aufnr.
  29.     gt_alv-bukrs = <fs_aufk>-bukrs.
  30.     gt_alv-werks = <fs_aufk>-werks.
  31.     gt_alv-erdat = <fs_aufk>-erdat.

  33.     CALL FUNCTION 'K_ORDER_CHECK'
  34.       EXPORTING
  35.         aufnr       = gt_alv-aufnr
  36.       EXCEPTIONS
  37.         not_allowed = 1
  38.         not_found   = 2
  39.         no_gsber    = 3
  40.         wrong_auart = 4
  41.         wrong_autyp = 5
  42.         wrong_bukrs = 6
  43.         wrong_gsber = 7
  44.         wrong_kokrs = 8
  45.         OTHERS      = 9.
  46.     IF sy-subrc NE 0.
  47.       gt_alv-zid = icon_red_light.
  48.       MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4 INTO gt_alv-zmessage.
  49.     ELSE.
  50.       IF p_del = 'X'.
  51.         CALL FUNCTION 'STATUS_CHECK'
  52.           EXPORTING
  53.             client            = sy-mandt
  54.             objnr             = <fs_aufk>-objnr
  55.             status            = 'I0076' "DLFL        删除标记
  56.           EXCEPTIONS
  57.             object_not_found  = 1
  58.             status_not_active = 2
  59.             OTHERS            = 3.
  60.         IF sy-subrc = 0.
  61.           gt_alv-zid = icon_red_light.
  62.           gt_alv-zmessage  = '已是删除状态'.
  63.         ENDIF.
  64.       ENDIF.
  65.     ENDIF.

  67.     APPEND gt_alv.
  68.   ENDLOOP.

  70. ENDFORM.                    " FRM_DATA_CHECK
  71. *&---------------------------------------------------------------------*
  72. *&      Form  FRM_SHOW_ALV
  73. *&---------------------------------------------------------------------*
  74. *       text
  75. *----------------------------------------------------------------------*
  76. *  -->  p1        text
  77. *  <--  p2        text
  78. *----------------------------------------------------------------------*
  79. FORM frm_show_alv .
  80. *局部变量定义
  81.   DATA: ls_layout   TYPE lvc_s_layo,
  82.         lt_fieldcat TYPE lvc_t_fcat,
  83.         ls_fieldcat TYPE lvc_s_fcat,
  84.         lt_event    TYPE slis_t_event WITH HEADER LINE,
  85.         pos         TYPE i,
  86.         w_repid     LIKE sy-repid VALUE sy-repid.

  88.   " 初始化
  89.   CLEAR: ls_layout,
  90.          lt_fieldcat[],ls_fieldcat,
  91.          lt_event[],lt_event,pos.

  93. * ALV参数设置
  94.   ls_layout-box_fname   = 'FLAG'.
  95.   ls_layout-cwidth_opt    = 'X'.
  96.   ls_layout-detailinit    = 'X'.

  98.   "  fieldcat设置
  99.   DEFINE d_get_field.
  100.     pos = pos + 1.
  101.     CLEAR ls_fieldcat.
  102.     ls_fieldcat-col_pos = pos.
  103.     ls_fieldcat-coltext = &1.
  104.     ls_fieldcat-fieldname = &2.
  105.     ls_fieldcat-key       = &3.
  106.     APPEND ls_fieldcat TO lt_fieldcat.
  107.   END-OF-DEFINITION.
  108.   d_get_field '错误信号'          'ZID'        ''.
  109.   d_get_field '消息文本'          'ZMESSAGE'   ''.
  110.   d_get_field '生产订单'          'AUFNR'      'X'.
  111.   d_get_field '公司代码'          'BUKRS'      ''.
  112.   d_get_field '工厂'              'WERKS'      ''.
  113.   d_get_field '创建日期'          'ERDAT'      ''.

  115. * ALV 展示
  116.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
  117.     EXPORTING
  118.       i_callback_program       = w_repid
  119.       i_callback_pf_status_set = 'SUB_STATUS'
  120.       i_callback_user_command  = 'SUB_COMMAND'
  121.       is_layout_lvc            = ls_layout
  122.       it_fieldcat_lvc          = lt_fieldcat
  123.       i_save                   = 'A'
  124.       it_events                = lt_event[]
  125.     TABLES
  126.       t_outtab                 = gt_alv[]
  127.     EXCEPTIONS
  128.       program_error            = 1
  129.       OTHERS                   = 2.
  130.   IF sy-subrc <> 0.
  131.     LEAVE TO SCREEN 0.
  132.   ENDIF.
  133. ENDFORM.                    " FRM_SHOW_ALV
  134. *&---------------------------------------------------------------------*
  135. *&      Form  SUB_STATUS
  136. *&---------------------------------------------------------------------*
  137. *       text
  138. *----------------------------------------------------------------------*
  139. *  -->  p1        text
  140. *  <--  p2        text
  141. *----------------------------------------------------------------------*
  142. FORM sub_status USING re_extab TYPE slis_t_extab.
  143.   SET PF-STATUS 'ZSTATUS01'.
  144. ENDFORM.
  145. *&---------------------------------------------------------------------*
  146. *&      Form  SUB_COMMAND
  147. *&---------------------------------------------------------------------*
  148. *       text
  149. *----------------------------------------------------------------------*
  150. *  -->  p1        text
  151. *  <--  p2        text
  152. *----------------------------------------------------------------------*
  153. FORM sub_command USING r_ucomm LIKE sy-ucomm
  154.                        rs_selfield TYPE slis_selfield.

  156.   CASE r_ucomm.
  157.     WHEN 'BACK'.
  158.       LEAVE TO SCREEN 0.
  159.     WHEN '&DATA_SAVE'.
  160.       SORT gt_alv BY flag zid.
  161.       READ TABLE gt_alv WITH KEY flag = 'X' zid = icon_red_light BINARY SEARCH.
  162.       IF sy-subrc = 0.
  163.         MESSAGE '请检查报错信息的条目！' TYPE 'E'.
  164.       ENDIF.
  165.       READ TABLE gt_alv WITH KEY  flag = 'X' BINARY SEARCH.
  166.       IF sy-subrc NE 0.
  167.         MESSAGE '请选择需要导入的数据！' TYPE 'E'.
  168.       ENDIF.
  169.       PERFORM frm_save_data.
  170.     WHEN OTHERS.
  171.   ENDCASE.

  173.   rs_selfield-refresh = 'X'.  " 刷新.
  174. ENDFORM.
  175. *&---------------------------------------------------------------------*
  176. *&      Form  FRM_SAVE_DATA
  177. *&---------------------------------------------------------------------*
  178. *       text
  179. *----------------------------------------------------------------------*
  180. *  -->  p1        text
  181. *  <--  p2        text
  182. *----------------------------------------------------------------------*
  183. FORM frm_save_data .
  184.   DATA:lv_objnr   TYPE jsto-objnr.
  185.   DATA:ls_message TYPE zots001.

  187.   LOOP AT gt_alv ASSIGNING FIELD-SYMBOL(<fs_alv>) WHERE flag = 'X'.
  188.     CLEAR:ls_message,lv_objnr.
  189.     IF p_del = 'X'. "设置删除
  190.       CALL FUNCTION 'ZPPFM008'
  191.         EXPORTING
  192.           i_order_number = <fs_alv>-aufnr
  193.         IMPORTING
  194.           e_message      = ls_message.
  195.       IF ls_message-type = 'S'.
  196.         <fs_alv>-zid = icon_green_light.
  197.       ELSE.
  198.         <fs_alv>-zid = icon_red_light.
  199.       ENDIF.
  200.       <fs_alv>-zmessage = ls_message-message.
  201.     ELSEIF p_cal = 'X'."取消删除
  202.       "LVMS 删除标识   LVMZ 去掉删除标记
  203.       lv_objnr = 'OR' && <fs_alv>-aufnr.
  204.       CALL FUNCTION 'STATUS_CHANGE_FOR_ACTIVITY'
  205.         EXPORTING
  206.           objnr                = lv_objnr
  207.           vrgng                = 'LVMZ'
  208.         EXCEPTIONS
  209.           activity_not_allowed = 1
  210.           object_not_found     = 2
  211.           status_inconsistent  = 3
  212.           status_not_allowed   = 4
  213.           wrong_input          = 5
  214.           warning_occured      = 6
  215.           OTHERS               = 7.
  216.       IF sy-subrc = 0.
  217.         UPDATE aufk SET loekz = '' WHERE aufnr = <fs_alv>-aufnr.
  218.         COMMIT WORK.

  220.         <fs_alv>-zid = icon_green_light.
  221.         <fs_alv>-zmessage = '取消删除成功'.
  222.       ELSE.
  223.         <fs_alv>-zid = icon_red_light.
  224.         MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4 INTO <fs_alv>-zmessage.
  225.       ENDIF.
  226.     ENDIF.
  227.   ENDLOOP.

  229. ENDFORM.                    " FRM_SAVE_DATA
复制代码
ZPPFM008 生产订单删除
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 858 主题
  2. 125 回帖
  3. 11755 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2026-3-14 16:32 , Processed in 0.058752 second(s), 5 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表