MIRO采购发票预制过账BAPI_INCOMINGINVOICE_CREATE1

FUNCTION zpufm040.
*"----------------------------------------------------------------------
*"*"本地接口：
*" IMPORTING
*" VALUE(I_HEADER) TYPE ZPUS049 OPTIONAL
*" EXPORTING
*" VALUE(E_MESSAGE) TYPE ZOTS001
*" VALUE(E_BELNR) TYPE RE_BELNR
*" VALUE(E_GJAHR) TYPE GJAHR
*" TABLES
*" IT_ITEM STRUCTURE ZPUS050 OPTIONAL
*"----------------------------------------------------------------------
DATA: ls_headerdata TYPE bapi_incinv_create_header,
lv_invoicestatus TYPE bapi_incinv_create_status-rbstat,
lv_invoicedocnumber TYPE bapi_incinv_fld-inv_doc_no,
lv_fiscalyear TYPE bapi_incinv_fld-fisc_year,
lv_msage TYPE string.
DATA: lt_itemdata TYPE STANDARD TABLE OF bapi_incinv_create_item,
lt_return TYPE STANDARD TABLE OF bapiret2.
DATA: ls_itemdata LIKE LINE OF lt_itemdata,
ls_return LIKE LINE OF lt_return.
IF it_item[] IS NOT INITIAL.
SELECT ebeln,
ebelp,
meins,
bprme,
bpumz,
bpumn
FROM ekpo
FOR ALL ENTRIES IN @it_item
WHERE ebeln = @it_item-ebeln
AND ebelp = @it_item-ebelp
INTO TABLE @DATA(lt_ekpo).
ENDIF.
* 1. 填充抬头数据 (HEADERDATA)
ls_headerdata-doc_type = 'RE'. " 凭证类型，如RE（应付发票）
ls_headerdata-invoice_ind = 'X'. " X 表示这是一张需要过账的正向发票，空表示这是一张冲销发票
ls_headerdata-ref_doc_no = i_header-xblnr." 外部参考编号
ls_headerdata-comp_code = i_header-bukrs." 公司代码
ls_headerdata-doc_date = i_header-bldat." 凭证日期
ls_headerdata-pstng_date = i_header-budat." 过账日期
ls_headerdata-gross_amount = i_header-rmwwr." 总金额（含税）
ls_headerdata-currency = i_header-waers." 货币
ls_headerdata-header_txt = i_header-bktxt." 抬头文本
ls_headerdata-diff_inv = |{ i_header-lifnr ALPHA = IN }|." 供应商编号
ls_headerdata-calc_tax_ind = i_header-xmwst." 自动计算税额标识
* 设置发票状态为“过账”
lv_invoicestatus = i_header-rbstat."5 已过账 A 预制
* 2. 填充行项目数据 (ITEMDATA)
* 注意: BUZEI 必须按升序排列
SORT lt_ekpo BY ebeln ebelp.
LOOP AT it_item ASSIGNING FIELD-SYMBOL(<fs_item>).
CLEAR:ls_itemdata.
ls_itemdata-invoice_doc_item = sy-tabix. " 发票行项目编号
ls_itemdata-po_number = <fs_item>-ebeln." 采购订单号
ls_itemdata-po_item = <fs_item>-ebelp." 采购订单行项目
ls_itemdata-quantity = <fs_item>-menge." 数量
ls_itemdata-po_unit = <fs_item>-bstme." 单位
ls_itemdata-item_amount = <fs_item>-wrbtr." 此行总金额（含税）
ls_itemdata-item_text = <fs_item>-sgtxt." 行文本
READ TABLE lt_ekpo ASSIGNING FIELD-SYMBOL(<fs_ekpo>) WITH KEY ebeln = <fs_item>-ebeln ebelp = <fs_item>-ebelp BINARY SEARCH.
IF sy-subrc = 0 AND <fs_ekpo>-bprme NE ls_itemdata-po_unit.
ls_itemdata-po_pr_qnt = <fs_item>-menge / <fs_ekpo>-bpumn * <fs_ekpo>-bpumz.
ls_itemdata-po_pr_uom = <fs_ekpo>-bprme.
ENDIF.
SELECT SINGLE
mseg~ebeln,
mseg~ebelp,
mseg~mblnr,
mseg~mjahr,
mseg~zeile
FROM mseg
INNER JOIN mkpf ON mseg~mblnr = mkpf~mblnr AND mseg~mjahr = mkpf~mjahr
WHERE mseg~ebeln = @<fs_item>-ebeln
AND mseg~ebelp = @<fs_item>-ebelp
AND mseg~smbln = '' "排除冲销的物料凭证
AND mkpf~blart = 'WE' "WE 收货物料凭证
AND NOT EXISTS ( SELECT * FROM m_mbmps
WHERE m_mbmps~smbln = mseg~mblnr
AND m_mbmps~sjahr = mseg~mjahr
AND m_mbmps~smblp = mseg~zeile )
INTO @DATA(ls_mseg).
IF sy-subrc = 0.
ls_itemdata-ref_doc = ls_mseg-mblnr.
ls_itemdata-ref_doc_year = ls_mseg-mjahr.
ls_itemdata-ref_doc_it = ls_mseg-zeile.
ENDIF.
APPEND ls_itemdata TO lt_itemdata.
ENDLOOP.
* 3. 调用BAPI
CALL FUNCTION 'BAPI_INCOMINGINVOICE_CREATE1'
EXPORTING
headerdata = ls_headerdata
invoicestatus = lv_invoicestatus
IMPORTING
invoicedocnumber = lv_invoicedocnumber
fiscalyear = lv_fiscalyear
TABLES
itemdata = lt_itemdata
return = lt_return.
* 4. 处理返回结果
LOOP AT lt_return INTO ls_return WHERE type CA 'AXE'.
CLEAR:lv_msage.
CALL FUNCTION 'MESSAGE_TEXT_BUILD'
EXPORTING
msgid = ls_return-id
msgnr = ls_return-number
msgv1 = ls_return-message_v1
msgv2 = ls_return-message_v2
msgv3 = ls_return-message_v3
msgv4 = ls_return-message_v4
IMPORTING
message_text_output = lv_msage.
IF e_message-message IS INITIAL.
e_message-message = lv_msage.
ELSE.
CONCATENATE e_message-message lv_msage INTO e_message-message SEPARATED BY '/'.
ENDIF.
ENDLOOP.
IF sy-subrc = 0."失败
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
e_message-type = 'E'.
ELSE.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
wait = 'X'.
e_message-type = 'S'.
e_message-message = '创建采购发票成功'.
e_belnr = lv_invoicedocnumber.
e_gjahr = lv_fiscalyear.
ENDIF.
ENDFUNCTION.

复制代码

[BAPI] MIRO采购发票预制过账BAPI_INCOMINGINVOICE_CREATE1

Ta最近发表

快速回帖