二维码

[函数] 取消POD交货确认 接口

Twilight发表于 2026-11-19 13:58Twilight 最后回复于 2026-11-19 13:58 [复制链接] 6 0

取消POD交货证明,没有标准BAPI,详见VLPOD交货单客户签收POD确认
  1. FUNCTION zsdfm084.
  2. *"----------------------------------------------------------------------
  3. *"*"本地接口:
  4. *"  IMPORTING
  5. *"     VALUE(I_VBELN) TYPE  VBELN_VL
  6. *"  EXPORTING
  7. *"     VALUE(E_MESSAGE) TYPE  ZOTS001
  8. *"----------------------------------------------------------------------
  9.   DATA:lt_messtab     TYPE TABLE OF bdcmsgcoll.
  10.   DATA:lt_return      TYPE TABLE OF bapiret2.
  11.   DATA:ls_opt_params  TYPE ctu_params.
  12.   DATA:lv_pdstk       TYPE likp-pdstk.

  13. *初始化
  14.   i_vbeln = |{ i_vbeln ALPHA = IN }|.

  15. *检查
  16.   SELECT SINGLE pdstk INTO lv_pdstk FROM likp WHERE vbeln = i_vbeln.
  17.   IF lv_pdstk = ''.
  18.     e_message-type = 'S'.
  19.     e_message-message = '交货单' && i_vbeln && '未启用POD,无需取消POD交货确认'.
  20.     EXIT.
  21.   ELSEIF lv_pdstk = 'A'.
  22.     e_message-type = 'S'.
  23.     e_message-message = '已经取消POD交货确认,无需再次取消'.
  24.     EXIT.
  25.   ENDIF.

  26. *BDC录屏赋值
  27.   PERFORM bdc_dynpro      USING 'SAPMV50A' '4006'.
  28.   PERFORM bdc_field       USING 'BDC_CURSOR'
  29.                                 'LIKP-VBELN'.
  30.   PERFORM bdc_field       USING 'BDC_OKCODE'
  31.                                 '=ENT2'.
  32.   PERFORM bdc_field       USING 'LIKP-VBELN'
  33.                                 i_vbeln.

  34.   PERFORM bdc_dynpro      USING 'SAPMV50A' '1000'.
  35.   PERFORM bdc_field       USING 'BDC_OKCODE'
  36.                                 '=PODS'.

  37.   PERFORM bdc_dynpro      USING 'SAPMV50A' '1000'.
  38.   PERFORM bdc_field       USING 'BDC_OKCODE'
  39.                                 '=SICH_T'.

  40. *BDC调用模式参数
  41.   ls_opt_params-dismode  = 'N'.
  42.   ls_opt_params-updmode  = 'S'.
  43.   ls_opt_params-racommit = 'X'.

  44.   CALL TRANSACTION 'VLPOD' USING  bdcdata OPTIONS FROM ls_opt_params
  45.                            MESSAGES INTO lt_messtab.
  46.   IF sy-subrc = 0.
  47.     e_message-type    = 'S'.
  48.     e_message-message = '取消POD交货确认成功!'.
  49.   ELSE.
  50.     CALL FUNCTION 'CONVERT_BDCMSGCOLL_TO_BAPIRET2'
  51.       TABLES
  52.         imt_bdcmsgcoll = lt_messtab
  53.         ext_return     = lt_return.
  54.     LOOP AT lt_return ASSIGNING FIELD-SYMBOL(<fs_return>) WHERE type CA 'AEX'.
  55.       IF e_message-message IS INITIAL.
  56.         e_message-message = <fs_return>-message.
  57.       ELSE.
  58.         e_message-message = e_message-message && '/' && <fs_return>-message.
  59.       ENDIF.
  60.     ENDLOOP.
  61.     e_message-type    = 'E'.
  62.   ENDIF.

  63. ENDFUNCTION.
  64. *----------------------------------------------------------------------*
  65. *        Start new screen                                              *
  66. *----------------------------------------------------------------------*
  67. FORM bdc_dynpro USING program dynpro.
  68.   CLEAR bdcdata.
  69.   bdcdata-program  = program.
  70.   bdcdata-dynpro   = dynpro.
  71.   bdcdata-dynbegin = 'X'.
  72.   APPEND bdcdata.
  73. ENDFORM.
  74. *----------------------------------------------------------------------*
  75. *        Insert field                                                  *
  76. *----------------------------------------------------------------------*
  77. FORM bdc_field USING fnam fval.
  78.   IF fval <>  '/'.
  79.     CLEAR bdcdata.
  80.     bdcdata-fnam = fnam.
  81.     bdcdata-fval = fval.
  82.     APPEND bdcdata.
  83.   ENDIF.
  84. ENDFORM.
复制代码
回复

使用道具 举报

快速回帖

本版积分规则
您需要登录后才可以回帖 登录 | 注册有礼

快速回复 返回顶部 返回列表