MIRO采购发票预制过账BAPI_INCOMINGINVOICE_CREATE1

1. FUNCTION zpufm040.
   
2. *"----------------------------------------------------------------------
   
3. *"*"本地接口：
   
4. *"  IMPORTING
   
5. *"     VALUE(I_HEADER) TYPE  ZPUS049 OPTIONAL
   
6. *"  EXPORTING
   
7. *"     VALUE(E_MESSAGE) TYPE  ZOTS001
   
8. *"     VALUE(E_BELNR) TYPE  RE_BELNR
   
9. *"     VALUE(E_GJAHR) TYPE  GJAHR
   
10. *"  TABLES
    
11. *"      IT_ITEM STRUCTURE  ZPUS050 OPTIONAL
    
12. *"----------------------------------------------------------------------
    
13.   DATA: ls_headerdata       TYPE bapi_incinv_create_header,
    
14.         lv_invoicestatus    TYPE bapi_incinv_create_status-rbstat,
    
15.         lv_invoicedocnumber TYPE bapi_incinv_fld-inv_doc_no,
    
16.         lv_fiscalyear       TYPE bapi_incinv_fld-fisc_year,
    
17.         lv_msage            TYPE string.
    
18. 
    
19.   DATA: lt_itemdata TYPE STANDARD TABLE OF bapi_incinv_create_item,
    
20.         lt_return   TYPE STANDARD TABLE OF bapiret2.
    
21. 
    
22.   DATA: ls_itemdata LIKE LINE OF lt_itemdata,
    
23.         ls_return   LIKE LINE OF lt_return.
    
24. 
    
25. * 1. 填充抬头数据 (HEADERDATA)
    
26.   ls_headerdata-doc_type     = 'RE'.          " 凭证类型，如RE（应付发票）
    
27.   ls_headerdata-invoice_ind  = 'X'.           " X 表示这是一张需要过账的正向发票，空 表示这是一张冲销发票
    
28.   ls_headerdata-ref_doc_no   = i_header-xblnr." 外部参考编号
    
29.   ls_headerdata-comp_code    = i_header-bukrs." 公司代码
    
30.   ls_headerdata-doc_date     = i_header-bldat." 凭证日期
    
31.   ls_headerdata-pstng_date   = i_header-budat." 过账日期
    
32.   ls_headerdata-gross_amount = i_header-rmwwr." 总金额（含税）
    
33.   ls_headerdata-currency     = i_header-waers." 货币
    
34.   ls_headerdata-header_txt   = i_header-bktxt." 抬头文本
    
35.   ls_headerdata-diff_inv     = |{ i_header-lifnr ALPHA = IN }|." 供应商编号
    
36.   ls_headerdata-calc_tax_ind = i_header-xmwst." 自动计算税额标识
    
37. 
    
38. * 设置发票状态为“过账”
    
39.   lv_invoicestatus           = i_header-rbstat."5        已过账 A        预制
    
40. 
    
41. * 2. 填充行项目数据 (ITEMDATA)
    
42. * 注意: BUZEI 必须按升序排列
    
43.   LOOP AT it_item ASSIGNING FIELD-SYMBOL(<fs_item>).
    
44.     ls_itemdata-invoice_doc_item = sy-tabix.       " 发票行项目编号
    
45.     ls_itemdata-po_number        = <fs_item>-ebeln." 采购订单号
    
46.     ls_itemdata-po_item          = <fs_item>-ebelp." 采购订单行项目
    
47.     ls_itemdata-quantity         = <fs_item>-menge." 数量
    
48.     ls_itemdata-po_unit          = <fs_item>-bstme." 单位
    
49.     ls_itemdata-item_amount      = <fs_item>-wrbtr." 此行总金额（含税）
    
50.     ls_itemdata-item_text        = <fs_item>-sgtxt." 行文本
    
51. 
    
52.     SELECT SINGLE
    
53.             mseg~ebeln,
    
54.             mseg~ebelp,
    
55.             mseg~mblnr,
    
56.             mseg~mjahr,
    
57.             mseg~zeile
    
58.     FROM mseg
    
59.     INNER JOIN mkpf ON mseg~mblnr = mkpf~mblnr AND mseg~mjahr = mkpf~mjahr
    
60.     WHERE mseg~ebeln = @<fs_item>-ebeln
    
61.       AND mseg~ebelp = @<fs_item>-ebelp
    
62.       AND mseg~smbln = ''  "排除冲销的物料凭证
    
63.       AND mkpf~blart = 'WE' "WE 收货物料凭证
    
64.       AND NOT EXISTS ( SELECT * FROM m_mbmps
    
65.                       WHERE m_mbmps~smbln = mseg~mblnr
    
66.                         AND m_mbmps~sjahr = mseg~mjahr
    
67.                         AND m_mbmps~smblp = mseg~zeile )
    
68.       INTO @DATA(ls_mseg).
    
69.     IF sy-subrc = 0.
    
70.       ls_itemdata-ref_doc      = ls_mseg-mblnr.
    
71.       ls_itemdata-ref_doc_year = ls_mseg-mjahr.
    
72.       ls_itemdata-ref_doc_it   = ls_mseg-zeile.
    
73.     ENDIF.
    
74.     APPEND ls_itemdata TO lt_itemdata.
    
75.   ENDLOOP.
    
76. 
    
77. * 3. 调用BAPI
    
78.   CALL FUNCTION 'BAPI_INCOMINGINVOICE_CREATE1'
    
79.     EXPORTING
    
80.       headerdata       = ls_headerdata
    
81.       invoicestatus    = lv_invoicestatus
    
82.     IMPORTING
    
83.       invoicedocnumber = lv_invoicedocnumber
    
84.       fiscalyear       = lv_fiscalyear
    
85.     TABLES
    
86.       itemdata         = lt_itemdata
    
87.       return           = lt_return.
    
88. 
    
89. * 4. 处理返回结果
    
90.   LOOP AT lt_return INTO ls_return WHERE type CA 'AXE'.
    
91.     CLEAR:lv_msage.
    
92.     CALL FUNCTION 'MESSAGE_TEXT_BUILD'
    
93.       EXPORTING
    
94.         msgid               = ls_return-id
    
95.         msgnr               = ls_return-number
    
96.         msgv1               = ls_return-message_v1
    
97.         msgv2               = ls_return-message_v2
    
98.         msgv3               = ls_return-message_v3
    
99.         msgv4               = ls_return-message_v4
    
100.       IMPORTING
     
101.         message_text_output = lv_msage.
     
102.     IF e_message-message IS INITIAL.
     
103.       e_message-message   = lv_msage.
     
104.     ELSE.
     
105.       CONCATENATE e_message-message lv_msage INTO e_message-message SEPARATED BY '/'.
     
106.     ENDIF.
     
107.   ENDLOOP.
     
108.   IF sy-subrc = 0."失败
     
109.     CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
     
110.     e_message-type   = 'E'.
     
111.   ELSE.
     
112.     CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
     
113.       EXPORTING
     
114.         wait = 'X'.
     
115.     e_message-type    = 'S'.
     
116.     e_message-message = '创建采购发票成功'.
     
117.     e_belnr = lv_invoicedocnumber.
     
118.     e_gjahr = lv_fiscalyear.
     
119.   ENDIF.
     
120. 
     
121. ENDFUNCTION.

复制代码