编辑alv需要输出的fieldcatalog然后alv输出这些字段

需要创建screen 600、定义工具栏、逻辑流和container容器等，程序代码里有英文说明

程序代码：

1. *&---------------------------------------------------------------------*
   
2. *& AS : ALV report which displays the contents of the table T006
   
3. *& (as a docking container in the bottom) along with the
   
4. *& editable ALV which contains the ALV fieldcatalogue table structure.
   
5. *& With the available toolbar options of the editable ALV in the output,
   
6. *& user can change the fieldcatalogue as per his requirement.
   
7. *& When the user clicks 'SUBMIT',the display of the ALV with table T006
   
8. *& gets modified and customised accordingly to the user's requirement.
   
9. *&---------------------------------------------------------------------*
   
10. REPORT  ydamon_042.
    
11. * Output table T006 structure declaration
    
12. TYPES : BEGIN OF ty_t006.
    
13.         INCLUDE STRUCTURE t006.
    
14. TYPES : END OF ty_t006.
    
15. *Internal table and wa declaration for T006
    
16. DATA : it_t006 TYPE STANDARD TABLE OF ty_t006,
    
17.        wa_t006 TYPE ty_t006.
    
18. *declarations for ALV
    
19. DATA: ok_code               TYPE sy-ucomm,
    
20. * fieldcatalog for T006
    
21.       it_fielcat           TYPE lvc_t_fcat,
    
22. * fieldcatalog for fieldcatalog itself:
    
23.       it_fielcatalogue           TYPE lvc_t_fcat,
    
24.       it_layout           TYPE lvc_s_layo.
    
25. *declaration for toolbar function
    
26. DATA:   it_excl_func        TYPE ui_functions.
    
27. 
    
28. * Controls to display it_t006 and corresponding fieldcatalog
    
29. DATA: cont_dock TYPE REF TO cl_gui_docking_container,
    
30.       cont_alvgd     TYPE REF TO cl_gui_alv_grid.
    
31. *controls to display the fieldcatalog as editable alv grid and container
    
32. DATA: cont_cust TYPE REF TO cl_gui_custom_container,
    
33.       cont_editalvgd     TYPE REF TO cl_gui_alv_grid.
    
34. *intialization event
    
35. INITIALIZATION.
    
36. *start of selection event
    
37. START-OF-SELECTION.
    
38. 
    
39. **************************************************************
    
40. * LOCAL CLASS Definition for data changed in fieldcatalog ALV
    
41. **************************************************************
    
42. CLASS lcl_event_receiver DEFINITION.
    
43.   PUBLIC SECTION.
    
44.     METHODS handle_data_changed
    
45.       FOR EVENT data_changed OF cl_gui_alv_grid
    
46.       IMPORTING er_data_changed.
    
47. ENDCLASS.                    "lcl_event_receiver DEFINITION
    
48. **************************************************************
    
49. * LOCAL CLASS implementation for data changed in fieldcatalog ALV
    
50. **************************************************************
    
51. CLASS lcl_event_receiver IMPLEMENTATION.
    
52.   METHOD handle_data_changed.
    
53.   ENDMETHOD.                    "handle_data_changed
    
54. ENDCLASS.                    "lcl_event_receiver IMPLEMENTATION
    
55. *data declaration for event receiver
    
56. DATA: event_receiver TYPE REF TO lcl_event_receiver.
    
57. *end of selection event
    
58. END-OF-SELECTION.
    
59. *setting the screen for alv output for table display and
    
60. *changed fieldcatalalogue display
    
61.   SET SCREEN 600.
    
62. 
    
63. *On this statement double click  it takes you to the screen painter SE51.
    
64. * Enter the attributes
    
65. *Create a Custom container and name it CCONT and OK code as OK_CODE.
    
66. *Save check and Activate the screen painter.
    
67. *Now a normal screen with number 600 is created which holds the ALV grid.
    
68. * PBO of the actual screen , Here we can give a title and customized menus
    
69. *Go to SE41 and create status 'STATUS600' and create THE function code 'SUBMIT'
    
70. *and 'EXIT' with icons and icon texts
    
71. *Also create a TitleBar 'TITLE600' and give the relevant title.
    
72. *&---------------------------------------------------------------------*
    
73. *&      Module  STATUS_0600  OUTPUT
    
74. *&---------------------------------------------------------------------*
    
75. MODULE status_0600 OUTPUT.
    
76.   SET PF-STATUS 'STATUS600'.
    
77.   SET TITLEBAR 'TITLE600'.
    
78. * CREATE ALV GRID CONTROL IF DOES NOT EXISTS INITIALLY
    
79.   IF cont_dock IS INITIAL.
    
80.     PERFORM create_alv.
    
81.   ENDIF.
    
82. ENDMODULE.                             " STATUS_0600  OUTPUT
    
83. * PAI module of the screen created. In case we use an interactive ALV or
    
84. *for additional functionalities we can create OK codes and based on the
    
85. *user command we can do the coding as shown below
    
86. *&---------------------------------------------------------------------*
    
87. *&      Module  USER_COMMAND_0600  INPUT
    
88. *&---------------------------------------------------------------------*
    
89. MODULE user_command_0600 INPUT.
    
90.   CASE ok_code.
    
91.     WHEN 'SUBMIT'.
    
92. *TO GET THE CURRENT FIELDCATALOGUE FROM THE FRONTEND
    
93.       CALL METHOD cont_alvgd->set_frontend_fieldcatalog
    
94.         EXPORTING
    
95.           it_fieldcatalog = it_fielcat.
    
96. *refresh the alv
    
97.       CALL METHOD cont_alvgd->refresh_table_display.
    
98. *to Send Buffered Automation Queue to Frontend
    
99.       CALL METHOD cl_gui_cfw=>flush.
    
100. *Exit button clicked to leave the program
     
101.     WHEN 'EXIT'.
     
102.       LEAVE PROGRAM.
     
103.   ENDCASE.
     
104. ENDMODULE.                             " USER_COMMAND_0600  INPUT
     
105. *&---------------------------------------------------------------------*
     
106. *&      Form  CREATE_ALV
     
107. *&---------------------------------------------------------------------*
     
108. FORM create_alv.
     
109. *create a docking container and dock the control at the botton
     
110.   CREATE OBJECT cont_dock
     
111.       EXPORTING
     
112.            dynnr = '600'
     
113.            extension = 100
     
114.            side = cl_gui_docking_container=>dock_at_bottom.
     
115. *create the alv grid for display the table
     
116.   CREATE OBJECT cont_alvgd
     
117.       EXPORTING
     
118.            i_parent = cont_dock.
     
119. *create custome container for alv
     
120.   CREATE OBJECT cont_cust
     
121.       EXPORTING
     
122.            container_name = 'CCONT'.
     
123. *create alv editable grid
     
124.   CREATE OBJECT cont_editalvgd
     
125.       EXPORTING
     
126.            i_parent = cont_cust.
     
127. * register events for the editable alv
     
128.   CREATE OBJECT event_receiver.
     
129.   SET HANDLER event_receiver->handle_data_changed FOR cont_editalvgd.
     
130.   CALL METHOD cont_editalvgd->register_edit_event
     
131.     EXPORTING
     
132.       i_event_id = cl_gui_alv_grid=>mc_evt_modified.
     
133. *building the fieldcatalogue for the initial display
     
134.   PERFORM build_fieldcat CHANGING it_fielcat it_fielcatalogue.
     
135. *building the fieldcatalogue after the user has changed it
     
136.   PERFORM change_fieldcat CHANGING it_fielcatalogue.
     
137. *fetch data from the table
     
138.   PERFORM fetch_data.
     
139. *    Get excluding functions for the alv editable tool bar
     
140.   APPEND cl_gui_alv_grid=>mc_fc_loc_append_row TO it_excl_func.
     
141.   APPEND cl_gui_alv_grid=>mc_fc_loc_insert_row TO it_excl_func.
     
142.   APPEND cl_gui_alv_grid=>mc_fc_loc_cut TO it_excl_func.
     
143.   APPEND cl_gui_alv_grid=>mc_fc_sort TO it_excl_func.
     
144.   APPEND cl_gui_alv_grid=>mc_fc_sort_asc TO it_excl_func.
     
145.   APPEND cl_gui_alv_grid=>mc_fc_sort_dsc TO it_excl_func.
     
146.   APPEND cl_gui_alv_grid=>mc_fc_subtot TO it_excl_func.
     
147.   APPEND cl_gui_alv_grid=>mc_fc_sum TO it_excl_func.
     
148.   APPEND cl_gui_alv_grid=>mc_fc_graph TO it_excl_func.
     
149.   APPEND cl_gui_alv_grid=>mc_fc_info TO it_excl_func.
     
150.   APPEND cl_gui_alv_grid=>mc_fc_print TO it_excl_func.
     
151.   APPEND cl_gui_alv_grid=>mc_fc_filter TO it_excl_func.
     
152.   APPEND cl_gui_alv_grid=>mc_fc_views TO it_excl_func.
     
153.   APPEND cl_gui_alv_grid=>mc_mb_export TO it_excl_func.
     
154.   APPEND cl_gui_alv_grid=>mc_mb_sum TO it_excl_func.
     
155.   APPEND cl_gui_alv_grid=>mc_mb_sum TO it_excl_func.
     
156.   APPEND cl_gui_alv_grid=>mc_mb_paste TO it_excl_func.
     
157.   APPEND cl_gui_alv_grid=>mc_fc_find TO it_excl_func.
     
158.   APPEND cl_gui_alv_grid=>mc_fc_loc_copy  TO it_excl_func.
     
159. 
     
160. *Alv display for the T006 table at the bottom
     
161.   CALL METHOD cont_alvgd->set_table_for_first_display
     
162.     CHANGING
     
163.       it_outtab       = it_t006[]
     
164.       it_fieldcatalog = it_fielcat[].
     
165. 
     
166. * optimize column width of grid displaying fieldcatalog
     
167.   it_layout-cwidth_opt = 'X'.
     
168. * Get fieldcatalog of table T006 - alv might have
     
169. * modified it after passing.
     
170.   CALL METHOD cont_alvgd->get_frontend_fieldcatalog
     
171.     IMPORTING
     
172.       et_fieldcatalog = it_fielcat[].
     
173. *to Send Buffered Automation Queue to Frontend
     
174.   CALL METHOD cl_gui_cfw=>flush.
     
175. * Display fieldcatalog of table T006 in editable alv grid
     
176.   CALL METHOD cont_editalvgd->set_table_for_first_display
     
177.     EXPORTING
     
178.       is_layout            = it_layout
     
179.       it_toolbar_excluding = it_excl_func
     
180.     CHANGING
     
181.       it_outtab            = it_fielcat[]
     
182.       it_fieldcatalog      = it_fielcatalogue[].
     
183. 
     
184. ENDFORM.                               " CREATE_alv
     
185. *&---------------------------------------------------------------------*
     
186. *&      Form  fetch_data
     
187. *&---------------------------------------------------------------------*
     
188. FORM fetch_data.
     
189. * select data of T006
     
190.   SELECT * FROM t006 INTO TABLE it_t006 UP TO 50 ROWS.
     
191. 
     
192. ENDFORM.                               " fetch_data
     
193. *&---------------------------------------------------------------------*
     
194. *&      Form  BUILD_FIELDCAT
     
195. *&---------------------------------------------------------------------*
     
196. FORM build_fieldcat CHANGING it_fldcat TYPE lvc_t_fcat
     
197.                                    it_fcat TYPE lvc_t_fcat.
     
198. 
     
199. * Fieldcatalog for table T006: it_fldcat
     
200. * to generate the fields automatically
     
201.   CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
     
202.     EXPORTING
     
203.       i_structure_name       = 'T006'
     
204.     CHANGING
     
205.       ct_fieldcat            = it_fldcat[]
     
206.     EXCEPTIONS
     
207.       inconsistent_interface = 1
     
208.       program_error          = 2
     
209.       OTHERS                 = 3.
     
210.   IF sy-subrc <> 0.
     
211. * MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
     
212. *         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
     
213.   ENDIF.
     
214. *----------------------------------------------------
     
215. * Fieldcatalog for table LVC_T_FCAT:it_fcat
     
216. *----------------------------------------------------
     
217. * Generate fieldcatalog of fieldcatalog structure.
     
218. * This fieldcatalog is used to display fieldcatalog 'it_fldcat'
     
219. * on the top of the screen.
     
220.   CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
     
221.     EXPORTING
     
222.       i_structure_name       = 'LVC_S_FCAT'
     
223.     CHANGING
     
224.       ct_fieldcat            = it_fcat[]
     
225.     EXCEPTIONS
     
226.       inconsistent_interface = 1
     
227.       program_error          = 2
     
228.       OTHERS                 = 3.
     
229.   IF sy-subrc <> 0.
     
230. * MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
     
231. *         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
     
232.   ENDIF.
     
233. 
     
234. ENDFORM.                               " BUILD_FIELDCAT
     
235. 
     
236. *&---------------------------------------------------------------------*
     
237. *&      Form  CHANGE_FIELDCAT
     
238. *&---------------------------------------------------------------------*
     
239. *after the user has modified the fieldcatalogue we build another fieldcat
     
240. *for the modified alv display
     
241. FORM change_fieldcat CHANGING it_fcat TYPE lvc_t_fcat.
     
242.   DATA ls_fcat TYPE lvc_s_fcat.
     
243.   LOOP AT it_fcat INTO ls_fcat.
     
244.     ls_fcat-coltext = ls_fcat-fieldname.
     
245.     ls_fcat-edit = 'X'.
     
246.     IF ls_fcat-fieldname = 'COL_POS' OR ls_fcat-fieldname = 'FIELDNAME'.
     
247.       ls_fcat-key = 'X'.
     
248.     ENDIF.
     
249.     MODIFY it_fcat FROM ls_fcat.
     
250.   ENDLOOP.
     
251. ENDFORM.                               " CHANGE_FIELDCAT

复制代码

程序执行效果：

输出报表时我们不用考虑“MANDT”，现在我们编辑alv的一些字段（例如 直接删除一些字段），然后单击submit按钮，输出如下